SET SOFTSEEK
 Activa o desactiva la búsqueda aproximada
------------------------------------------------------------------------------
 Sintaxis

     SET SOFTSEEK on | OFF | <xlConmutar>

 Argumentos

     ON hace que el puntero del registro se desplace al siguiente
     registro con una clave mayor tras una búsqueda no satisfactoria en el
     índice.

     OFF hace que el puntero del registro se desplace al final del
     fichero tras una búsqueda no satisfactoria en el índice.

     <xlConmutar> es una expresión lógica que debe figurar entre
     paréntesis. El valor verdadero (.T.) equivale a ON (activar) y el valor
     falso (.F.) a OFF (desactivar).

 Descripción

     SET SOFTSEEK activa la búsqueda aproximada, un método de búsqueda en un
     índice que devuelve un registro aunque no exista coincidencia para una
     clave determinada.

     Cuando se establece SET SOFTSEEK ON y no se encuentra un registro
     coincidente, el puntero del registro se sitúa en el siguiente registro
     del índice que tenga un valor clave superior al argumento de SEEK. Los
     registros que no son visibles por acción de los mandatos SET FILTER y/o
     SET DELETED se ignoran cuando se efectúa la búsqueda del siguiente
     valor clave mayor. Si no existe ningún registro con un valor clave
     mayor, el puntero del registro se sitúa en LASTRECT() + 1, EOF()
     devuelve el valor verdadero (.T.) y FOUND() devuelve el valor falso
     (.F.). FOUND() sólo devuelve el valor verdadero (.T.) si se encuentra
     realmente el registro. Nunca devuelve el valor verdadero (.T.) para una
     clave aproximada.

     Cuando se establece SET SOFTSEEK OFF y una búsqueda no resulta
     satisfactoria, el puntero del registro se sitúa en LASTREC() +1, EOF()
     devuelve el valor verdadero (.T.) y FOUND() devuelve el valor falso
      (.F.).

 Notas

     ■ SET RELATION: SET RELATION ignora la actualización del puntero
        del registro efectuada por SOFTSEEK en todas las áreas de trabajo
        hijas enlazadas, al igual que si SOFTSEEK estuviese en OFF.

 Ejemplos

      Este ejemplo ilustra los posibles resultados de una búsqueda
        con SET SOFTSEEK ON:

        SET SOFTSEEK ON
        USE Vendedor INDEX Vendedor NEW
        ACCEPT "Introducir Vendedor: " TO cBusqueda
        SEEK cBusqueda
        DO CASE
        CASE FIELD->Vendedor = cBusqueda
           ? "Coincidencia encontrada:", FOUND(), EOF(), FIELD->Vendedor
        CASE !EOF()
           ? "Coincidencia aproximada encontrada:", FOUND(), EOF(), ;
                     FIELD->Vendedor
        OTHERWISE
           ? "Ninguna clave coincide:", FOUND(), EOF(), FIELD->Vendedor
        ENDCASE

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: FOUND() SEEK SET INDEX SET ORDER SET RELATION