<> != #
 Distinto a -binario                             (Relacional)
------------------------------------------------------------------------------
 Sintaxis

     <exp1> <> <exp2>
     <exp1> != <exp2>
     <exp1> #  <exp2>

 Tipo

     Carácter, fecha, lógico, memo, NIL, numérico

 Operandos

     <exp1> y <exp2> son las expresiones de datos del mismo tipo o
     NIL, que se van a comparar.

 Descripción

     El operador distinto a (<>) es un operador binario que compara dos
     valores del mismo tipo de datos y devuelve verdadero (.T.) si <exp1> es
     diferente de <exp2>, según las siguientes normas:

     ■ Carácter: la comparación se establece a partir del código
        ASCII correspondiente. Esto significa que la comparación tiene en
        cuenta el valor de SET EXACT actual. Consulte los ejemplos
        siguientes.

     ■ Fecha: Las fechas se comparan de acuerdo con el valor de fecha
        correspondiente.

     ■ Lógico: Falso (.F.) no es igual a verdadero (.T.).

     ■ Memo: Se trata igual que el tipo carácter.

     ■ Numérico: Se comparan de acuerdo a la magnitud.

     ■ NIL: Todas los expresiones que se comparen con NIL, excepto el
        mismo NIL, devuelven verdadero (.T.).

 Ejemplos

      Estos ejemplos muestran el comportamiento del operador
        distinto (<>) con distintos tipos de datos:

        // Carácter
        SET EXACT ON
        ? "123" <> "12345"           // Resultado: .T.
        ? "12345" <> "123"           // Resultado: .T.
        ? "123" <> ""                // Resultado: .T.
        ? "" <> "123"                // Resultado: .T.
        SET EXACT OFF
        ? "123" <> "12345"           // Resultado: .T.
        ? "12345" <> "123"           // Resultado: .F.
        ? "123" <> ""                // Resultado: .F.
        ? "" <> "123"                // Resultado: .T.

        // Fecha
        ? CTOD("12/12/88") <> ;
           CTOD("12/12/88")          // Resultado: .F.

        // Lógico
        ? .T. <> .T.                 // Resultado: .F.
        ? .T. <> .F.                 // Resultado: .T.

        // NIL
        ? NIL <> NIL                 // Resultado: .F.
        ? NIL <> 12                  // Resultado: .T.
        ? NIL <> "hola"              // Resultado: .T.

        // Numérico
        ? 2 <> 1                     // Resultado: .T.
        ? 1 <> 1                     // Resultado: .F.

 To download this example - click here.

See Also: $ < <= = (igualdad) == > >=