= (igualdad)
 Igual-binario                                   (Relacional)
------------------------------------------------------------------------------
 Sintaxis

     <exp1> = <exp2>

 Tipo

     Carácter, fecha, lógico, memo, NIL, numérico

 Operandos

     <exp1> y <exp2> son las expresiones de datos del mismo tipo,
      que se van a comparar.

 Descripción

     El operador (=) igual es un operador binario que compara valores de
     datos del mismo tipo y devuelve verdadero (.T.) si <exp1> es igual a
     <exp2>, según las reglas siguientes:

     ■ Carácter: la comparación se establece a partir del código
        ASCII correspondiente. Los códigos ASCII para caracteres
        alfanuméricos van en orden ascendente (p. e., el código para la "A"
        es 65 y el código para la "Z" es 90).

        Si se ha establecido SET EXACT OFF, las dos cadenas de caracteres se
        comparan de acuerdo con las reglas siguientes: supongamos dos
        cadenas de caracteres, cIzquierda y cDerecha, y la expresión que se
        va a comprobar es (cIzquierda = cDerecha):

        - Si cDerecha es nula, devuelve verdadero (.T.).

        - Si LEN(cDerecha) es mayor que LEN(cIzquierda), devuelve falso
            (.F.).

        - Compara todos los caracteres de cDerecha con los de
           cIzquierda. Si todos los caracteres de cDerecha son iguales a los
           de cIzquierda, devuelve verdadero (.T.); en caso contrario
           devuelve falso (.F.).

        Si se ha establecido SET EXACT ON, las dos cadenas deben coincidir
        exactamente, excepto en los espacios en blanco finales.

     ■ Fecha: Las fechas se comparan de acuerdo con el valor de fecha
        correspondiente.

     ■ Lógico: Verdadero (.T.) es igual a verdadero (.T.) y falso
        (.F.) es igual a falso (.F.).

     ■ Memo: Se trata igual que el tipo carácter.

     ■ NIL: Verdadero (.T.) si se compara con un valor NIL; falso
        (.F.) si se compara con un valor de cualquier otro tipo de datos.

     ■ Numérico: Se comparan de acuerdo con la magnitud.

 Ejemplos

      Estos ejemplos muestran el comportamiento del operador igual
        que (=) con distintos tipos de datos:

        // Carácter
        SET EXACT ON
        ? "123" = "123  "            // Resultado: .T.
        ? " 123" = "123"             // Resultado: .F.
        SET EXACT OFF
        ? "123" = "12345"            // Resultado: .F.
        ? "12345" = "123"            // Resultado: .T.
        ? "123" = ""                 // Resultado: .T.
        ? "" = "123"                 // Resultado: .F.

        // Fecha
        ? CTOD("12/12/88") = ;
           CTOD("12/12/88")          // Resultado: .T.

        // Lógico
        ? .T. = .T.                  // Resultado: .T.
        ? .F. = .T.                  // Resultado: .F.

        // NIL
        ? NIL = NIL                  // Resultado: .T.
        ? NIL = 12                   // Resultado: .F.
        ? NIL = CTOD("")             // Resultado: .F.

        // Numérico
        ? 2 = 1                      // Resultado: .F.
        ? 1 = 1                      // Resultado: .T.

 To download this example - click here.

See Also: $ < <= <> == > >=