BLOBDIRECTGET()
 Recupera datos almacenados en un fichero BLOB sin hacer referencia a un
 campo específico.
------------------------------------------------------------------------------
 Sintaxis

     BLOBDIRECTGET(<nPuntero>, [<nInicio>], [<nContador>])
        --> expBLOB

 Argumentos

     <nPuntero> es un puntero a los datos BLOB. Es posible obtener el
     puntero utilizando BLOBDIRECTPUT(), BLOBDIRECTIMPORT() y
     DBFIELDINFO(DBS_BLOB_POINTER, <nPosCampo>).

     <nInicio> es la posición de comienzo en <nPuntero>. Si <nInicio> es
     mayor que cero, la posición de comienzo es relativa al car cter m s a
     la izquierda de <nPuntero>. Si <nInicio> es menor que cero, la
     posición es relativa al car cter m s a la derecha de <nPuntero>. Si se
     omite <nInicio>, el valor por defecto es 1.

     <nContador> es el número de bytes de datos que se recuperan a
     partir de la posición <nInicio>. Si <nContador> es mayor que la
     cantidad de datos almacenados, se ignora el exceso. Si se omite este
     argumento, BLOBDIRECTGET() recupera datos hasta el final.

     Nota: <nInicio> y <nContador> sólo se utilizan con cadenas de
     caracteres. Se ignoran si se utilizan con cualquier otro tipo de
     datos.

 Devuelve

     BLOBDIRECTGET () devuelve los datos recuperados del fichero BLOB. El
     tipo de datos del valor devuelto depende de los datos almacenados.
     Utilice VALTYPE() para conocer el tipo de datos.

 Descripción

     BLOBDIRECTGET() recupera datos almacenados en un fichero BLOB sin la
     necesidad de hacer referencia a un campo particular de la base de
     datos. Es útil para acceder a datos que sobrepasan los 64 KB (como por
     ejemplo, los campos memo creados con la función BLOBIMPORT()).

     Por defecto, esta función opera en el  rea de trabajo seleccionada. Si
     desea utilizarla en otra  rea de trabajo, debe especificarla con una
     expresión de alias.

 Ejemplos

      Este ejemplo ilustra el almacenamiento de información de
        configuración en un fichero BLOB y la recuperación posterior de
        parte de la información:

        FUNCTION GuardarConfig(aColores, ;
                        aVias, ;
                        aContrasenyas)

           LOCAL aConfigs

           RDDSETDEFAULT ( "DBFCDX")
           MEMOSETSUPER ( "DBFCDX")

           USE Config NEW VIA "DBFMEMO"

           aConfigs := {}
           AADD(aConfigs, BLOBDIRECTPUT(0, aColores))
           AADD(aConfigs, BLOBDIRECTPUT(0, aVias))
           AADD(aConfigs, BLOBDIRECTPUT(0, aContrasenyas))

           BLOBROOTPUT (aConfigs)

           CLOSE

        FUNCTION GETCOLORES()
           LOCAL aConfigs
           LOCAL aColores

           USE Config NEW VIA "DBFMEMO"

           aConfigs := BLOBROOTGET()
           aColores := BLOBDIRECTGET(aConfigs[1])

           CLOSE


           RETURN aColores

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: BLOBDIRECTPUT() BLOBGET() BLOBIMPORT() DBFIELDINFO()