DBFIELDINFO()
 Devuelve y opcionalmente modifica la información acerca de un campo.
------------------------------------------------------------------------------
 Sintaxis

     DBFIELDINFO(<nTipoInfo>, <nPosCampo>,
        [<expNuevosValores>]) --> uValoresActuales

 Argumentos

     <nTipoInfo> determina el tipo de información utilizando las
     constantes de la tabla siguiente. Recuerde, no obstante, que algunas de
     estas constantes no están disponibles en todos los RDD ni pueden
     utilizarse en todos los tipos de campo. El fichero con la declaración
     de las constantes, Dbstruct.ch, debe incluirse (#include) en la
     aplicación.

     Constantes del tipo de información del campo
     ------------------------------------------------------------------------
     Constante                Descripción
     ------------------------------------------------------------------------
     DBS_BLOB_LEN             Devuelve el tamaño de almacenamiento de
                              los datos de un fichero BLOB (memo).
     DBS_BLOB_OFFSET          Devuelve el desplazamiento de los datos en
                              un fichero BLOB (memo).
     DBS_BLOB_POINTER         Devuelve un puntero numérico a los datos de
                              un fichero BLOB. El puntero devuelto puede
                              utilizarse con BLOBDIRECTGET(),
                              BLOBDIRECTIMPORT(),
                              etc.
     DBS_BLOB_TYPE            Devuelve el tipo de los datos de un campo
                              BLOB (memo). Este método es más eficiente que
                              TYPE() y VALTYPE() ya que no necesita recuperar
                              los datos del fichero BLOB para determinar
                              su tipo.
     DBS_DEC                  Número de decimales del campo.
     DBS_LEN                  Tamaño del campo.
     DBS_NAME                 Nombre del campo.
     DBS_TYPE                 Tipo de datos del campo.
     ------------------------------------------------------------------------

     <nPosCampo> es la posición del campo en la estructura del fichero
     de base de datos.

     <expNuevosValores> está reservado para uso futuro. Se puede omitir
     o establecerse en NIL.

 Devuelve

     DBFIELDINFO() devuelve los parámetros actuales del campo.

 Descripción

     DBFIELDINFO() obtiene información del estado de un campo. Por defecto,
     opera con el área de trabajo seleccionada. Si desea utilizarla en otra
     área de trabajo, debe especificarla con una expresión de alias.

     La información del campo que se obtiene depende del RDD.

     En esta versión de CA-Clipper se ha ampliado el número de RDD, de forma
     que es posible obtener información de campos y columnas de otros
     modelos de bases de datos (como por ejemplo diccionarios). El diseño de
     DBFIELDINFO() admite que desarrolladores externos de RDD definan nuevos
     valores para <nTipoInfo>.

 Ejemplos

      El ejemplo siguiente utiliza DBFIELDINFO() para obtener
        información acerca de un campo:

        #include Dbstruct.ch
        QOut(DBFIELDINFO(DBS_NAME, 1))        // Idéntico a FIELDNAME()
        FUNCTION OBTENERESTRUCTURA()
           LOCAL aEstructura := {}
           LOCAL nFContador, i

           nFContador := FCOUNT()
           FOR i:= 1 TO nFContador
              AADD(aEstructura, {FIELDNAME(i),  ;
                                DBFIELDINFO(DBS_TYPE, i),  ;
                                DBFIELDINFO(DBS_LEN, i),  ;
                                DBFIELDINFO(DBS_DEC, i)})
           NEXT
           RETURN aEstructura

 Ficheros   La biblioteca asociada es CLIPPER.LIB,
            el fichero de cabecera asociado es Dbstruct.ch.
 To download this example - click here.

See Also: DBINFO() DBORDERINFO() DBRECORDINFO()