DBGOBOTTOM() 
 Desplaza el puntero al último registro lógico
------------------------------------------------------------------------------
 Sintaxis

     DBGOBOTTOM() --> NIL

 Devuelve

     DBGOBOTTOM() devuelve siempre NIL.

 Descripción

     DBGOBOTTOM() desplaza el puntero al último registro lógico en el área
     de trabajo actual.

     DBGOBOTTOM() realiza la misma función que un mandato GO BOTTOM
     estándar. Si desea más información, consulte el mandato GO.

 Notas

     ■ Registros lógicos: DBGOBOTTOM() actúa con registros lógicos.
        Si existe un índice activo, DBGOBOTTOM() se desplaza al último
        registro en el orden del índice. Si se selecciona un filtro, sólo se
        procesan los registros que cumplan la condición del filtro.

     ■ Orden de control: Si hay activo más de un índice en el área de
        trabajo, la operación se ejecuta utilizando el orden de control
        establecido por la función DBSETORDER() o el mandato SET ORDER. Si
        desea más información, consulte el mandato SET ORDER.

     ■ Entorno de red: Al desplazarse a otro registro en un fichero
        compartido en red, las modificaciones efectuadas en el registro
        actual se hacen visibles a otros procesos. Si desea más información,
        consulte el capítulo "Programación en Red" en la Guía de
        Programación y Utilidades. Esta función no modifica el estado de
        bloqueo de los registros.

 Ejemplos

      En el ejemplo siguiente se utiliza DBGOBOTTOM() para situar el
        puntero en el último registro lógico:

        cApellido := "Rodríguez"
        DBUSEAREA(.T., "DBFNTX", "Ventas", "Ventas", .T.)
        DBSETINDEX( "APELLIDO" )
        //
        Ventas->( DBGOBOTTOM() )
        IF ( Ventas->Apellido == "Rodríguez" )
           IF RLOCK()
              Ventas->( DBDELETE() )
              ? "Registro borrado: ", Ventas->( DELETED() )
           ELSE
              ? "No es posible bloquear el registro..."
           ENDIF
        END

 Ficheros   La biblioteca asociada es CLIPPER.LIB.
 To download this example - click here.

See Also: BOF() DBGOTOP() DBSEEK() DBSKIP() EOF() GO