DBRELATION()
 Devuelve la expresión de enlazado de una relación especificada
------------------------------------------------------------------------------
 Sintaxis

     DBRELATION(<nRelación>) --> cExpEnlace

 Argumentos

     <nRelación> es la posición de la relación deseada en la lista de
     relaciones del área de trabajo actual. Las relaciones están numeradas
     de acuerdo con el orden en el que se definieron con SET RELATION.

 Devuelve

     DBRELATION() devuelve una cadena de caracteres que contiene la
     expresión de enlazado de la relación especificada por <nRelación>. Si
     no existe ninguna relación para <nRelación>, DBRELATION() devuelve una
     cadena nula ("").

 Descripción

     DBRELATION() es una función de base de datos que se utiliza con
     DBRSELECT() para determinar la expresión de enlazado y el área de
     trabajo de una relación existente creada con el mandato SET RELATION.

     DBRELATION() devuelve la expresión de enlazado definida por la cláusula
     TO. DBRSELECT() devuelve el área de trabajo enlazada definida por la
     cláusula INTO.

     Por defecto, DBRELATION() opera en el área de trabajo actual. Si desea
     utilizarla en un área de trabajo no seleccionada, debe indicarla con
     una expresión de alias (consulte el ejemplo siguiente).

 Notas

     ■ Variables declaradas: Una cadena de caracteres devuelta por
        DBRELATION() puede no actuar correctamente cuando se recompila y se
        ejecuta utilizando el operador de macro (&), si la expresión
        original contiene referencias a variables locales o estáticas, o
        declaraciones que se resuelvan durante la compilación.

 Ejemplos

      Este ejemplo abre tres ficheros de base de datos, establece
        dos relaciones secundarias desde el área de trabajo superior, y
        muestra la expresión de enlazado para el área de trabajo
        secundaria:

        USE Facturas INDEX Facturas NEW
        USE Devoluciones INDEX Devoluciones NEW
        USE Cliente INDEX Cliente NEW
        SET RELATION TO NumCliente INTO Facturas, NumOrden ;
              INTO Devoluciones
        //
        ? DBRELATION(2)                         // Resultado: NumOrden

      Más tarde, puede utilizarse la misma expresión de enlazado
        desde un área de trabajo no seleccionada mediante una expresión con
        alias como ésta:

        USE Fichero NEW
        ? Cliente->(DBRELATION(2))              // Resultado: NumOrden

      Este ejemplo es una función definida por el usuario,
        Relacion(), que devuelve los resultados de DBRELATION() y
        DBRSELECT() como una matriz:

        FUNCTION Relacion( nRelacion )
           RETURN { DBRELATION(nRelacion), ;
                  ALIAS(DBRSELECT(nRelacion)) }

 Ficheros   La biblioteca asociada es CLIPPER.LIB.
 To download this example - click here.

See Also: DBFILTER() DBRSELECT() SET RELATION