DBSELECTAREA()
 Cambia el área de trabajo actual
------------------------------------------------------------------------------
 Sintaxis

     DBSELECTAREA(<nArea> | <cAlias>) --> NIL

 Argumentos

     <nArea> es un valor numérico comprendido entre 0 y 250, inclusive,
     que especifica el área de trabajo que se va a seleccionar.

     <cAlias> es un valor de caracteres que especifica el alias del área
     de trabajo ocupada actualmente que se va a seleccionar.

 Devuelve

     DBSELECTAREA() devuelve siempre NIL.

 Descripción

     DBSELECTAREA() hace que el área de trabajo especificada se convierta en
     el área de trabajo actual. Todas las operaciones de base de datos
     posteriores se aplican a este área de trabajo, a menos que se
     especifique explícitamente otra área de trabajo para una operación.
     DBSELECTAREA() realiza la misma función que un mandato SELECT
     estándar. Si desea más información, consulte el mandato SELECT.

 Notas

     ■ Selección cero: Si se selecciona un área de trabajo cero, el
        área de trabajo libre con el número más bajo se convierte en el área
        de trabajo actual.

     ■ Expresiones de alias: El operador de alias (->) puede
        seleccionar temporalmente un área de trabajo mientras se evalúa una
        expresión y, posteriormente, restablecer el área de trabajo
        anterior. Si desea más información, consulte el operador de alias
         (->).

 Ejemplos

      El ejemplo siguiente selecciona un área de trabajo mediante el
        nombre de alias:

        cApellido := "López"
        DBUSEAREA(.T., "DBFNTX", "Ventas", "Ventas", .T.)
        DBSETINDEX( "NOMBVEND" )
        DBSETINDEX( "APELVEND" )
        //
        DBUSEAREA(.T., "DBFNTX", "DISTRIBU", "DISTRIBU", .T.)
        DBSETINDEX( "NOMBDIST" )
        DBSETINDEX( "APELDIST" )
        //
        DBSELECTAREA( "Ventas" )     // seleccionar área de trabajo "Ventas"
        //
        IF ( Ventas->(DBSEEK(cApellido)) )
           IF Ventas->( DELETED() ) .AND. Ventas->( RLOCK() )
              Ventas->( DBRECALL() )
              ? "Se ha recuperado el registro borrado."
           ENDIF
        ELSE
           ? "No encontrado"
        ENDIF

 Ficheros   La biblioteca asociada es CLIPPER.LIB.
 To download this example - click here.

See Also: DBUSEAREA() RLOCK() UNLOCK SELECT SELECT() RLOCK()