EMPTY()
 Determina si el resultado de una expresión es un valor vacío
------------------------------------------------------------------------------
 Sintaxis

     EMPTY(<exp>) --> lVacío

 Argumentos

     <exp> es una expresión de cualquier tipo de datos.

 Devuelve

     EMPTY() devuelve verdadero (.T.) si la expresión es un valor vacío; de
     lo contrario, devuelve falso (.F.). Los criterios para determinar si un
     valor se considera vacío dependen del tipo de datos de <exp> de acuerdo
     con las reglas siguientes:

     Lista de Valores Vacíos
     ------------------------------------------------------------------------
     Tipo de datos            Contenido
     ------------------------------------------------------------------------
     Matriz                   Longitud cero
     Carácter                 Espacios, tabuladores, CR/LF, o ("")
     Numérico                 0
     Fecha                    CTOD("")
     Lógico                   Falso (.F.)
     Memo                     Igual que carácter
     NIL                      NIL
     ------------------------------------------------------------------------

 Descripción

     La función EMPTY() cuenta con diferentes utilizaciones. Puede
     utilizarla para determinar si un usuario ha introducido un valor en un
     objeto GET antes de realizar cambios en un fichero de base de datos.
     También puede determinar si un parámetro formal es NIL o no se ha
     pasado. Además, puede comprobar una matriz para ver si tiene longitud
     cero.

 Notas

     ■ Caracteres de espacio: La función EMPTY() trata los retornos
        de carro, saltos de línea y tabuladores como espacios de caracteres
        y los elimina también.

 Ejemplos

      Estos ejemplos ilustran la utilización de EMPTY() frente a
        varios tipos de datos diferentes:

        ? EMPTY(SPACE(5)), EMPTY("")            // Resultado: .T. .T.
        ? EMPTY(0), EMPTY(CTOD(""))             // Resultado: .T. .T.
        ? EMPTY(.F.), EMPTY(NIL)                // Resultado: .T. .T.

      Este ejemplo utiliza EMPTY() para determinar si el usuario ha
        introducido un valor en el primer objeto Get antes de escribir el
        nuevo valor en el fichero de base de datos:

        LOCAL cCliente := SPACE(15), nCantidad := 0
        USE Ventas NEW
        @ 10, 10 GET cCliente
        @ 11, 10 GET nCantidad PICTURE "999.99"
        READ
        //
        IF !EMPTY(cCliente)
           APPEND BLANK
           REPLACE Ventas->Cliente WITH cCliente,;
               Ventas->Cantidad WITH nCantidad
        ENDIF

      Este ejemplo utiliza EMPTY() como parte de la cláusula VALID
        para forzar al usuario a introducir datos en el objeto Get actual:

        LOCAL cCodigo := SPACE(5)
        @ 2, 5 SAY "Introduzca código" GET cCodigo VALID !EMPTY(cCodigo)
        READ

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: LEN()