FCOUNT() 
 Devuelve el número de campos del fichero .dbf actual
------------------------------------------------------------------------------
 Sintaxis

     FCOUNT() --> nCampos

 Devuelve

     FCOUNT() devuelve el número de campos del fichero de base de datos en
     el área de trabajo actual como un valor numérico entero. Si no hay
     ningún fichero de base de datos abierto, FCOUNT() devuelve cero.

 Descripción

     FCOUNT() es una función de base de datos. Es útil en aplicaciones que
     contienen programas independientes de los datos que pueden funcionar
     con cualquier fichero de base de datos. Estos incluyen programas
     genéricos de importación/exportación y de informes. Normalmente, debe
     utilizarse FCOUNT() para establecer el límite superior de un bucle
     FOR...NEXT o DO WHILE que procesa un campo cada vez.

     Por defecto, FCOUNT() funciona en el área de trabajo seleccionada
     actualmente.

 Ejemplos

      Este ejemplo ilustra FCOUNT(), devolviendo el número de campos
        del área de trabajo actual y de una no seleccionada:

        USE Ventas NEW
        USE Cliente NEW
        ? FCOUNT()                   // Resultado: 5
        ? Ventas->(FCOUNT())         // Resultado: 8

      Este ejemplo utiliza FCOUNT() para declarar una matriz con
        información de campo:

        LOCAL aCampos := ARRAY(FCOUNT())
        AFIELDS(aCampos)

      Este ejemplo utiliza FCOUNT() como límite superior de un bucle
        FOR que procesa la lista de los campos del área de trabajo actual:

        LOCAL nCampo
        USE Ventas NEW
        FOR nCampo := 1 TO FCOUNT()
           ? FIELD(nCampo)
        NEXT

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: AFIELDS()* FIELDNAME() TYPE()