FERASE() 
 Borra un fichero del disco
------------------------------------------------------------------------------
 Sintaxis

     FERASE(<cFichero>) --> nExito

 Argumentos

     <cFichero> es el nombre del fichero que debe borrarse del disco,
     incluyendo la extensión, y opcionalmente precedido por una
     especificación de unidad y/o vía.

 Devuelve

     FERASE() devuelve -1 si la operación falla y cero si es satisfactoria.
     En el caso de que se produzca un fallo, puede utilizarse FERROR() para
     determinar la naturaleza del error.

 Descripción

     FERASE() es una función de fichero que borra un fichero especificado
     del disco. FERASE() es igual que el mandato ERASE, pero devuelve un
     valor y puede especificarse dentro de una expresión. Cuando se llama a
     FERASE(), <cFichero> se borra del disco únicamente si se encuentra en
     el directorio del DOS actual o en el directorio especificado, de forma
     explícita, como parte del nombre del fichero. Al igual que otras
     funciones y mandatos de fichero, FERASE() no utiliza los valores de SET
     DEFAULT ni SET PATH para localizar <cFichero>.

     ¡Advertencia! Los ficheros deben cerrarse antes de borrarlos con
     FERASE().

 Ejemplos

      En este ejemplo se borra un conjunto de ficheros que coinciden
        con un patrón comodín:

        #include "Directry.ch"
        AEVAL(DIRECTORY("*.BAK"), { |aFichero| ;
           FERASE(aFichero[F_NAME]) })

      En este ejemplo se borra un fichero y se muestra un mensaje si
        falla la operación:

        IF FERASE("Fichero.txt") == -1
           ? "Error de borrado de archivo:", FERROR()
           BREAK
        ENDIF

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: CLOSE ERASE FERROR() FRENAME() RENAME