GFNTSET()
 Activa una fuente cargada en memoria
------------------------------------------------------------------------------
 Sintaxis

     GFNTSET(<aFuente>, [<nLímSup>, <nLímInf>])
        --> aInfo

 Argumentos

     <aFuente> es un puntero a la región VMM donde se ha cargado la
     fuente .FND. <aFuente> puede crearse con una llamada previa a
     GFNTLOAD().

     <nLímSup> y <nLímInf> especifican cuántas filas de píxeles se
     utilizan en la visualización estándar de texto. Con estos valores es
     posible dibujar un borde de un píxel de anchura alrededor de un GET.

 Devuelve

     GFNTSET() devuelve una matriz con dos elementos que contiene
     información del área de recorte de la fuente.

 Descripción

     GFNTSET() activa una fuente previamente cargada en memoria. Después de
     haber llamado a GFNTSET(), las llamadas a DEVOUT() utilizarán la nueva
     fuente. Esto significa que es posible utilizar varias fuentes .FND al
     mismo tiempo. Para volver a activar la fuente ROM estándar, utilice
     GFNTSET( LLG_FNT_ROM ). En GWRITEAT() puede utilizarse una fuente .FND
     del siguiente modo:

        aFuenteFnd := GFNTLOAD("FndPrueb.FND")
        nColor   := 3
        GWRITEAT(1, 1, "Cualquier texto ", nColor, LLG_MODE_SET, ; aFuenteFnd)

     GFNTSET() devuelve una matriz con dos elementos que contiene
     información sobre el área de recorte. La estructura de esta matriz es {
     nFilaPíxelSup, nFilaPíxelInf}. Con esta característica podrá ajustar el
     texto a una altura determinada. Es frecuente que se necesite dibujar un
     borde alrededor de un GET sin tener que ocupar una línea de texto por
     encima y otra por debajo del GET. DEVOUT() y los métodos de
     visualización de GET siempre visualizan un carácter sobreescribiendo el
     fondo. Por lo tanto, si se dibuja un borde alrededor del GET, parte de
     este borde desaparecerá en el momento en el que se visualice un
     carácter.

     La mayoría de las fuentes no utilizan las filas de píxeles superior e
     inferior. De esta manera es posible restringir o recortar la
     visualización de un carácter a las filas 1-14 (en lugar de 0-15) y
     preservar el borde de la acción de borrado que realizan
     DEVPOS()/DISPLAY().

 Ejemplos

      Este ejemplo utiliza fuentes de distinto tamaño:

        FUNCTION MostrarUnaFuente (cCadena)
           LOCAL aFuenteGrande, aFuentePequenya
                        // Carga un par de fuentes en memoria
           aFuenteGrande := GFNTLOAD("FntGrand.FND")
           aFuentePequenya := GFNTLOAD("FntPeque.FND")
                        // Establece FntGrand.FND como fuente activa.
                        // Después de llamar a GFNTSET(), @...SAY,
                        // DEVOUT() etc. utilizarán la nueva fuente.
        GFNTSET(aFuenteGrande)
           @1,1 SAY "Texto escrito con la fuente 'FntGrand.FND'"
                        // Visualiza texto con la fuente grande
           GWRITEAT(X , Y , "Utilizando la fuente grande...", ;
                        nColor, LLG_MODE_SET)
           GWRITEAT(X , Y , "Utilizando la fuente pequeña...", ;
                        nColor, LLG_MODE_SET, aFuentePequenya)
                        // Establece FntPeque.FND como fuente activa
           GFNTSET(aFuentePequenya)
                        // Visualiza texto con la fuente pequeña
           GWRITEAT(X , Y , " Utilizando la fuente pequeña...", ;
                        nColor, G_MODE_SET)
                        // Utiliza la fuente ROM estándar
           GFNTSET(G_FNT_ROM)
                        // Visualiza un texto
           GWRITEAT(X , Y , "Utilizando la fuente ROM...", ;
                        nColor, G_MODE_SET)
           // *Importante*  Debe borrar las fuentes cuando acabe de
           // utilizarlas, ya que CA-Clipper no libera de forma
           // automática la zona de memoria ocupada por una fuente.
           GFNTERASE(aFuenteGrande)
           GFNTERASE(aFuentePequenya)
           RETURN  NIL

 Ficheros   La biblioteca asociada es LLIBG.LIB,
            el fichero de cabecera asociado es Llibg.ch.

 To download this example - click here.

See Also: GFNTERASE() GFNTLOAD()