GSETPAL()
 Cambia los componentes de un color
------------------------------------------------------------------------------
 Sintaxis

     GSETPAL(<nColor>, <nValorRojo>, <nValorVerde>,
        <nValorAzul>) --> aAntPaleta

     GSETPAL() --> aAntPaleta

     GSETPAL(<aPaleta>) --> aAntPaleta

     GSETPAL(<nColor>, <aRGB>) --> aAntPaleta

 Argumentos

     <nColor> es un valor numérico que representa un color.

     Este valor está limitado por el número de colores disponibles en el
     modo de vídeo seleccionado. En un modo de 16 colores, los valores
     válidos están comprendidos entre 0 y 15. En un modo de 256 colores,
     entre 0 y 255.

     <nValorRojo> es un valor numérico que representa el componente rojo
     asignado a <nColor>. Sus posibles valores están comprendidos entre 0 y
     63.

     <nValorVerde> es un valor numérico que representa el componente
     verde asignado a <nColor>. Sus valores posibles están comprendidos
     entre 0 y 63.

     <nValorAzul> es un valor numérico que representa el componente azul
     asignado a <nColor>. Sus valores posibles están comprendidos entre 0 y
     63.

     <aPaleta> es una matriz de componentes de la paleta. La estructura
     de la matriz es {nValorRojo, nValorVerde, nValorAzul}.

     <aRGB> es una matriz de componentes de la paleta. La estructura de
     la matriz es {nValorRojo, nValorVerde, nValorAzul}.

 Devuelve

     <aAntPaleta> representa una matriz de componentes de la paleta:

     aAntPaleta := { nValorRojo, nValorVerde, nValorAzul }

 Descripción

     La función GSETPAL() modifica los valores de los componentes básicos de
     un color. Es preciso llamar a esta función para cada color si se quiere
     cambiar la paleta. Puede utilizarse tanto en modo texto como en modo
     gráfico.

 Notas

     CA-Clipper guarda el entorno VGA|VESA incluida la paleta. También
     guarda la primera llamada a GMODE() o a SET VIDEOMODE. Cuando la
     ejecución de la aplicación llega a un QUIT o alcanza el último RETURN,
     se restablece de forma automática el modo de vídeo inicial. No es
     necesario, por tanto, guardar la paleta de colores original.

 Ejemplos

      Este ejemplo almacena los componentes de color del modo de
        vídeo en una matriz multidimensional. El resultado es el mismo que
        cuando se llama a GSETPAL() sin parámetros:

        FUNCTION aGuardarPal()
           LOCAL aPal := {}
           LOCAL nI := 0

        // Para todos los colores del modo de vídeo actual
           FOR nI := 1 TO GMODE()[LLG_MODE_COLOR_MAX]
        // Guarda el identificador del color y sus componentes
              AADD(aPal, {nI-1,;
                  GSETPAL(nI-1)[1],;
                  GSETPAL(nI-1)[2],;
                  GSETPAL(nI-1)[3]})
           NEXT nI
           // Devuelve una matriz de matrices
           RETURN aPal

      Este ejemplo carga todos los componentes de color de un modo
        de vídeo utilizando una matriz multidimensional que contiene los
        componentes individuales:

        FUNCTION aRestaurarPal(aPaleta)
           LOCAL nI := 0
           // Para todos las submatrices de la matriz general
           FOR nI := 1 TO LEN(aPaleta)
           // Restablecer los componentes de color
              GSETPAL(aPaleta[nI,1],;
                  aPaleta[nI,2],;
                  aPaleta[nI,3],;
                  aPaleta[nI,4];)
           NEXT nI
           RETURN aPaleta

 Ficheros   La biblioteca asociada es LLIBG.LIB,
            el fichero de cabecera asociado es Llibg.ch.