GWRITEAT()
 Dibuja texto en modo gráfico sin color de fondo
------------------------------------------------------------------------------
 Sintaxis

     GWRITEAT(<nColInic>, <nFilaInic>, <cCadena>,[<nColor>],
        [<nModo>], [<aFuente>]) --> nAnchura

 Argumentos

     <nColInic> y <nFilaInic> definen las coordenadas en píxeles del
     texto.

     <cCadena> es un valor de caracteres que representa la cadena de
     texto que se va a visualizar.

     <nColor> es un valor numérico que representa un color. Si se omite
     este argumento, se utiliza el último color especificado en una llamada
     a una función de CA-Clipper.

     Este valor está limitado por el número de colores disponibles en el
     modo de vídeo seleccionado. En un modo de 16 colores, los valores
     válidos están comprendidos entre 0 y 15. En un modo de 256 colores,
     entre 0 y 255

     <nModo> es un valor numérico que representa el modo de
     visualización. Toma uno de los siguientes valores definidos en el
     fichero Llibg.ch:

     Constantes del modo de visualización
     ------------------------------------------------------------------------
     Constante                Descripción
     ------------------------------------------------------------------------
     LLG_MODE_SET             Se utiliza el modo SET (se cubren los
                              píxeles del fondo). Es el modo de
                              visualización más habitual.
     LLG_MODE_AND             Se utiliza el modo AND (se realiza un AND
                              entre los píxeles del dibujo y los del fondo).
     LLG_MODE_OR              Se utiliza el modo OR (se realiza un OR
                              entre los píxeles del dibujo y los del fondo).
     LLG_MODE_XOR             Se utiliza el modo XOR (se realiza un XOR
                              entre los píxeles del dibujo y los del fondo).
                              Consulte la nota más adelante.
     LLG_MODE_NIL             Permite calcular la anchura de la cadena de
                              caracteres sin mostrarla en pantalla.
                              Recuerde que las fuentes .FNT son
                              proporcionales, lo que significa que una "m"
                              y una "i" no tienen el mismo número de píxeles.
     ------------------------------------------------------------------------

     Nota: Este método permite mover objetos por la pantalla sin afectar
     al dibujo de fondo. Para restaurar el dibujo de fondo se debe repetir
     la misma llamada con el modo de visualización XOR. Si se omite el modo
     de visualización, se utiliza el último modo especificado en una llamada
     a una función de CA-Clipper.

     <aFuente> es un puntero (opcional) a una matriz de fuentes creado
     por la función GFNTLOAD ("MiFuente.FND"):

     FUNCTION MostrarUnaFuente (cCadena)
        LOCAL aFuente
        // Carga en memoria un fichero con una fuente
        aFuente := GFNTLOAD("MiFuente.FND")
        // Visualiza cCadena utilizando la fuente cargada

           GWRITEAT(X , Y , cCadena, nColor, LLG_MODE_SET, aFuente)
           // *Importante*
           // Debe borrar la fuente si no la va a usar más.
           GFNTERASE(aFuente)
           RETURN NIL

 Devuelve

     GWRITEAT() devuelve la anchura en píxeles del texto escrito.

 Descripción

     GWRITEAT() visualiza texto en modo gráfico sin color de fondo. Es
     importante no confundir las funciones DEVOUT() y GWRITEAT(). Aun en
     modo gráfico, debe seguir usando DEVPOS(), DEVOUT() y QOUT() para
     visualizar información. Las funciones asociadas a los GET, TBROWSE,
     etc. utilizan colores de fondo y de primer plano, y el texto sólo
     puede visualizarse en áreas cuyo tamaño sea un múltiplo del tamaño de
     fuente seleccionado.

 Notas

     GWRITEAT() es útil para realizar mejoras en la presentación gráfica,
     como por ejemplo incluir un título dentro de una ventana (de manera
     que no desaparezca el borde de la ventana), o mostrar información en un
     área gráfica controlando si se borra el fondo antes de cada nueva
     visualización (por ejemplo, al añadir un título a un mapa de bits).

     A diferencia de DEVOUT(), esta función sólo acepta coordenadas
     gráficas, lo que permite mostrar texto píxel a píxel. Ya que GWRITEAT()
     trabaja con coordenadas de píxel en lugar de coordenadas de fila y
     columna, nColInic y nFilaInic deben calcularse de forma manual. Esta
     función sólo puede utilizarse si se ha establecido el modo gráfico para
     la pantalla utilizando SET VIDEOMODE.

     GBMPDISP() respeta las restricciones definidas con GSETCLIP().

 Ejemplos

      Este ejemplo escribe un título transparente en el borde de un
        cuadro en relieve:

        // Cambia a modo gráfico
        SET VIDEOMODE TO LLG_VIDEO_VGA_640_480_16
        // Muestra un cuadro 3D de anchura fija 16x16x16x16
        DISPBOX(nSup, nIzq, nInf, nDer, LLG_BOX_GRAY_SQUARE)
        // Escribe el título transparente en el borde del cuadro
        GWRITEAT( nIzq * GMODE()[LLG_MODE_FONT_COL],;
        nSup  * GMODE()[LLG_MODE_FONT_ROW],;
        ALIAS(SELECT()),;
        4,;
        LLG_MODE_SET)
        QUIT                         // Fin de la aplicación

 Ficheros   La biblioteca asociada es LLIBG.LIB,
            el fichero de cabecera asociado es Llibg.ch.

 To download this example - click here.

See Also: GBMPDISP() GFNTLOAD() GLINE() GRECT()