LASTREC()
 Determina el número de registros del fichero actual .dbf
------------------------------------------------------------------------------
 Sintaxis

     LASTREC() | RECCOUNT()* --> nRegistros

 Devuelve

     LASTREC() devuelve el número de registros físicos en el fichero actual
     de base de datos, en forma de valor numérico entero. Los mandatos de
     filtrado como SET FILTER o SET DELETED no tienen efecto sobre el valor
     devuelto. LASTREC() devuelve cero si no hay ningún fichero de base de
     datos utilizado en el área de trabajo actual.

 Descripción

     LASTREC() es una función de base de datos que determina el número de
     registros físicos existentes en el fichero actual de base de datos.
     LASTREC() es idéntica a RECCOUNT(), que se incluye por razones de
     compatibilidad.

     Por defecto, LASTREC() actúa en el área de trabajo actualmente
     seleccionada. Para que opere sobre un área de trabajo no seleccionada,
     debe especificarse como parte de una expresión de alias (consulte el
     ejemplo siguiente).

     Nota: A pesar de que se ha ampliado la funcionalidad de RECNO()
     para abarcar el concepto de "identidad", la función LASTREC() continúa
     devolviendo sólo números de registro, no identidades. LASTREC() no
     posee funcionalidad ampliada, por lo que no es "sensible a la
     identidad".

 Ejemplos

      Este ejemplo muestra la relación entre LASTREC(), RECCOUNT() y
        COUNT:

        USE Ventas NEW
        ? LASTREC(), RECCOUNT()                  // Resultado: 84 84
        //
        SET FILTER TO Vendedor = "1001"
        COUNT TO nRegistros
        ? nRegistros, LASTREC()                  // Resultado: 14 84

      Este ejemplo utiliza una expresión de alias para acceder al
        número de registros de un fichero de base de datos abierto en un
        área de trabajo no seleccionada.

        USE Ventas NEW
        USE Cliente NEW
        ? LASTREC(), Ventas->(LASTREC())

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: COUNT EOF()