MEMOLINE()
 Extrae una línea de texto de la cadena de caracteres o campo memo
------------------------------------------------------------------------------
 Sintaxis

     MEMOLINE(<cCadena>,
        [<nLongitudLínea>],
        [<nNúmeroLínea>],
        [<nTamañoTabulador>],
        [<lSaltoLínea>]) --> cLínea

 Argumentos

     <cCadena> es el campo memo o cadena de caracteres del que se va a
     extraer una línea de texto.

     <nLongitudLínea> especifica el número de caracteres de línea y
     puede estar comprendido entre 4 y 254. Si no se especifica, la longitud
     de línea por defecto es 79.

     <nNúmeroLínea> es el número de línea que se va a extraer. Si no se
     especifica, el valor por defecto es uno.

     <nTamañoTabulador> define el tamaño del tabulador. Si no se
     especifica, el valor por defecto es cuatro. Si <nTamañoTabulador> es
     mayor o igual que <nLongitudLínea>, el tamaño de tabulador se convierte
     automáticamente en <nLongitudLínea> - 1.

     <lSaltoLínea> cambia el valor del salto automático de línea. Si se
     especifica el valor verdadero (.T.) se activa el salto de línea y si de
     especifica el valor falso (.F.) se desactiva. El valor por defecto es
     verdadero (.T.).

 Devuelve

     MEMOLINE() devuelve la línea de texto especificada por <nNúmeroLínea>
     en <cCadena>, como cadena de caracteres. Si la línea tiene menos
     caracteres que la longitud indicada, el valor de retorno se rellena con
     espacios en blanco. Si el número de línea es mayor que el número total
     de líneas de <cCadena>, MEMOLINE() devuelve una cadena nula ("").

     Si <lSaltoLínea> tiene el valor verdadero (.T.) y la longitud de línea
     indicada interrumpe la línea en mitad de una palabra, dicha palabra no
     se incluye en el valor de retorno, sino que se muestra al principio de
     la siguiente línea extraída mediante MEMOLINE().

     Si <lSaltoLínea> tiene el valor falso (.F.), MEMOLINE() devuelve
     solamente el número de caracteres especificado por la longitud de
     línea. La siguiente línea extraída por MEMOLINE() comienza en el
     carácter que va a continuación del siguiente retorno de carro forzado,
     y los caracteres intermedios no se procesan.

 Descripción

     MEMOLINE() es una función memo que se utiliza con MLCOUNT() para
     extraer líneas de texto de cadenas de caracteres y campos memo,
     basándose en el número de caracteres por línea. Es la función más
     sencilla de CA-Clipper para mostrar en pantalla campos memo y cadenas
     largas.

     La forma de utilización más fácil consiste en determinar el número de
     líneas del campo memo o de la cadena de caracteres utilizando MLCOUNT()
     con el mismo número de caracteres por línea, tamaño de tabulador y
     selección de salto de línea que va a utilizar con MEMOLINE(). Este
     valor puede utilizarse como límite superior de FOR...NEXT para extraer
     líneas del campo memo o de la cadena de caracteres mediante MEMOLINE()
     y procesarlas con cualquier combinación de funciones y mandatos de
     salida necesarios.

 Ejemplos

      Este ejemplo muestra el método general para mostrar en
        pantalla campos memo y cadenas de caracteres largas utilizando una
        combinación de las funciones MLCOUNT() y MEMOLINE():

        LOCAL nLongitudLinea := 40, nTamanoTabulador := 3,; lSaltoLinea := .T.
        LOCAL nLineas, nLineaActual
        USE Cliente INDEX NombreCli NEW
        //
        nLineas := MLCOUNT(NotasCli, nLongitudLinea,;
              nTamanoTabulador, lSaltoLinea)
        //
        SET PRINTER ON
        FOR nLineaActual := 1 TO nLineas
           ? MEMOLINE(NotasCli, nLongitudLinea, nLineaActual, ;
                   nTamanoTabulador, lSaltoLinea)
        NEXT
        SET PRINTER OFF

 Ficheros   La biblioteca asociada es EXTEND.LIB.

 To download this example - click here.

See Also: MEMOEDIT() MLCOUNT() MLPOS()