ORDSCOPE()
 Establece o elimina los límites de ámbito en el orden de control para los
 valores de las claves
------------------------------------------------------------------------------
 Sintaxis

     ORDSCOPE(<nAmbito>,[<expNuevoValor>]) --> uValorActual

 Argumentos

     <nAmbito> es un número que determina si la función hace referencia
     al límite superior (TOPSCOPE) o al límite inferior (BOTTOMSCOPE).

     Nota: Para utilizar las constantes TOPSCOPE y BOTTOMSCOPE, debe
     incluir en la aplicación (#include) el fichero de cabecera Ord.ch.

     <expNuevoValor> es el límite superior o inferior de los valores de
     las claves que se incluirán en el ámbito actual del orden de control.
     <expNuevoValor> puede ser una expresión cuyo tipo de datos coincida
     con el de la expresión clave del orden de control o un bloque de código
     que devuelva el tipo de datos correcto.

     Si se omite <expNuevoValor> o se establece a NIL, el ámbito toma
     valores por defecto. El valor por defecto del límite superior es el
     primer registro lógico del orden de control. El valor por defecto del
     límite inferior es el último registro lógico.

 Devuelve

     Si <expNuevoValor> no se especifica, ORDSCOPE() devuelve los valores
     actuales de los límites y los restablece a sus valores por defecto. Si
     <expNuevoValor> se especifica, la función establece nuevos límites y
     devuelve los anteriores.

 Descripción

     El rango establecido mediante ORDSCOPE() es inclusivo. En otras
     palabras, el valor de las claves que se incluyan en el ámbito debe ser
     mayor o igual que el límite superior y menor o igual que el límite
     inferior.

     Nota: Para consultar los límites actuales sin modificarlos, realice
     una llamada a la función DBORDERINFO() utilizando las constantes
     DBOI_SCOPETOP y DBOI_SCOPEBOTTOM.

 Ejemplos

      Este ejemplo muestra la utilización de ORDSCOPE() para
        establecer límites de ámbito en un orden:

        USE Amigos
        SET INDEX TO Edad

        // Se establece en 25 la edad menor del rango
        ORDSCOPE(TOPSCOPE, 25)

        // Se establece en 30 la edad mayor del rango
        ORDSCOPE(BOTTOMSCOPE, 30)
        LIST Edad                        // Muestra los registros con
                                         // 25 <= Edad <= 30

        // Cambia a 35 la edad mayor del rango
        ORDSCOPE(BOTTOMSCOPE, 35)
        LIST Edad                        // Muestra los registros con
                                         // 25 <= Edad <= 35

        // Inicializa el límite superior
        ORDSCOPE(TOPSCOPE, NIL)
        LIST Edad                        // Muestra los registros con
                                         // Edad <= 35

        // Inicializa el límite inferior
        ORDSCOPE(BOTTOMSCOPE, NIL)
        LIST Edad                        // Muestra todos los registros

 Ficheros   La biblioteca asociada es CLIPPER.LIB,
            el fichero de cabecera asociado es Ord.ch.

 To download this example - click here.

See Also: SET SCOPE SET SCOPEBOTTOM SET SCOPETOP