ORDSETRELATION()
 Relaciona el área de trabajo especificada con el área de trabajo actual
------------------------------------------------------------------------------
 Sintaxis

     ORDSETRELATION(<nArea> | <cAlias>, <bClave>, [<cClave>])
        --> NIL

 Argumentos

     <nArea> es el número del área de trabajo hija.

     <cAlias> es el alias del área de trabajo hija.

     <bClave> es un bloque de código que expresa la expresión relacional
     en forma ejecutable.

     <cClave> es una cadena de caracteres opcional que expresa la
     expresión relacional en forma ejecutable. Si <cClave> se especifica,
     debe ser equivalente a <bClave>. Si <cClave> se omite,
     ORDSETRELATION() utiliza una cadena de caracteres vacía ("").

 Devuelve

     ORDSETRELATION() devuelve siempre NIL.

 Descripción

     ORDSETRELATION() relaciona el área de trabajo especificada por <nArea>
     o <cAlias> (el área de trabajo hija) con el área de trabajo actual (el
     área de trabajo padre). Las relaciones que existan previamente
     permanecen activas.

     Al relacionar dos áreas de trabajo, se sincronizan las áreas de trabajo
     hija y padre. Cada vez que el área padre se mueve a un nuevo registro,
     en el área hija se produce, de forma automática, un desplazamiento. Si
     hay un orden de control en el área de trabajo hija, al mover el área de
     trabajo padre se produce, en el área hija, una operación automática de
     búsqueda; la clave de la búsqueda se basa en la expresión formada por
     <bClave> y/o <cClave>. Si el área de trabajo hija no tiene orden de
     control, al mover el área de trabajo padre se produce en la primera un
     desplazamiento automático; el número de registro al que se desplaza se
     basa en la expresión formada por <bClave> y/o <cClave>.

     ORDSETRELATION() es similar a DBSETRELATION() (y al mandato SET
     RELATION), pero además establece un ámbito sobre el orden del área de
     trabajo hija. Esto significa que al seleccionar el área de trabajo
     hija, sólo son visibles los registros relacionados con el registro
     actual del área padre. Esto permite una gestión sencilla de las
     relaciones uno-a-muchos. Si desea más información, consulte
     DBSETRELATION().

 Ejemplos

      Este ejemplo muestra todas las líneas de cada factura:

        USE Linea NEW VIA "DBFCDX"
        SET ORDER TO TAG NumFact

        USE Factura NEW VIA "DBFCDX"

        // Establece una relación selectiva entre Lineas y Factura
        ORDSETRELATION("Linea", {|| Factura->Numfact}, ;
           "Factura->NumFact")

        GO TOP
        DO WHILE !EOF()
           ? NumFact, FechaFact                // Muestra los campos de
                                               // la factura

           SELECT Linea
           // Sólo son visibles los registros correspondientes al
           // número de factura actual
           LIST " ", NumPieza, Cant, Precio
           SELECT Factura                      // Se desplaza a la
                                               // factura siguiente
           SKIP
        ENDDO

 Ficheros   La biblioteca asociada es CLIPPER.LIB.