READVAR()
 Devuelve el nombre de la variable del GET o MENU actual
------------------------------------------------------------------------------
 Sintaxis

     READVAR() --> cNombreVar

 Devuelve

     READVAR() devuelve el nombre de la variable asociada con el objeto Get
     actual o el de la variable asignada mediante el mandato MENU TO, como
     una cadena de caracteres en mayúsculas.

 Descripción

     READVAR() es una función de entorno que se utiliza, fundamentalmente,
     para generar ayudas sensibles al contexto para objetos Get y menús de
     barra. READVAR() sólo puede utilizarse con los mandatos READ o MENU TO.
     Si se utiliza durante cualquier otro estado de espera, como ACCEPT,
     INPUT, WAIT, ACHOICE(), DBEDIT() o MEMOEDIT(), devuelve una cadena
     nula (""). Es habitual acceder a ella desde un procedimiento SET KEY o
     una función definida por el usuario invocada con una cláusula WHEN o
     VALID de un objeto Get.

 Ejemplos

      Este ejemplo implementa un sistema sencillo de ayuda para
        objetos Get, utilizando un fichero de base de datos para almacenar
        el texto de ayuda. Cuando el usuario pulsa F1, se busca en el
        fichero de ayuda utilizando READVAR() como valor clave y, si existe
        texto de ayuda, se muestra en una ventana:

        #include "Inkey.ch"
        //
        SET KEY K_F1 TO ConsultaAyuda
        cCadena = SPACE(10)
        @ 5, 5 SAY "Intro:" GET cCadena
        READ
        RETURN

        FUNCTION ConsultaAyuda
           USE Ayuda INDEX Ayuda NEW
           SEEK READVAR()
           IF FOUND()
              MostrarAyuda(Ayuda->Tema)
           ELSE
              MostrarAyuda("No hay ayuda sobre " + READVAR())
           ENDIF
           CLOSE Ayuda
           RETURN NIL

        FUNCTION MostrarAyuda(cTema)
           LOCAL cPantalla := SAVESCREEN(5,5,15,70),;
                   cColor := SETCOLOR("BG+/B")
           //
           SET CURSOR OFF
           @ 5, 5 CLEAR TO 15, 70
           @ 5, 5 TO 15, 70 DOUBLE
           @ 5, 30 SAY " Ayuda para " + READVAR() + " "
           MEMOEDIT(cTema, 6, 7, 14, 68, .F.)
           //
           RESTSCREEN(5, 5, 15, 70, cPantalla)
           SETCOLOR(cColor)
           SET CURSOR ON
           //
           RETURN NIL

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: @...GET MENU TO READ SET KEY