RESTSCREEN()
 Muestra una zona de pantalla previamente guardada, en la posición
 especificada
------------------------------------------------------------------------------
 Sintaxis

     RESTSCREEN([<nSup>], [<nIzq>],
        [<nInf>], [<nDer>], <cPantalla>) --> NIL

 Argumentos

     <nSup>, <nIzq>, <nInf> y <nDer> definen las coordenadas
     de la información de pantalla contenida en <cPantalla>. Si no se
     especificaron coordenadas con <cPantalla> para que se guardara toda la
     pantalla, tampoco son necesarias con RESTSCREEN().

     <cPantalla> es una cadena de caracteres que contiene la zona de
     pantalla guardada.

 Devuelve

     RESTSCREEN() devuelve siempre NIL.

 Descripción

     RESTSCREEN() es una función de pantalla que vuelve a mostrar una zona
     de pantalla guardada con SAVESCREEN(). La posición de destino puede ser
     la posición de pantalla original u otra diferente. Si se especifica una
     nueva posición, la nueva zona debe tener el mismo tamaño que la antigua
     o se obtendrán resultados imprevistos. Al utilizar RESTSCREEN() para
     recuperar secciones de pantalla guardadas con SAVE SCREEN, pueden
     especificarse coordenadas comprendidas entre 0, 0 y MAXROW(),
     MAXCOL().

     ¡Advertencia! SAVE SCREEN, RESTORE SCREEN, SAVESCREEN() y
     RESTSCREEN() sólo pueden utilizarse con el controlador de pantalla por
     defecto (mapa de memoria del IBM PC). Otros controladores pueden no
     permitir guardar y recuperar las pantallas.

 Ejemplos

      Este ejemplo muestra RESTSCREEN() como parte de una función de
        menú emergente de uso general, MenuEmerg():

        ? MenuEmerg({1, 1, 3, 10, {"ElementoUno", "ElementoDos"}, ;
              "BG+/B"})

        FUNCTION MenuEmerg(aLista)
           LOCAL cPantalla, nSeleccion, cAnteriorColor := ;
                  SETCOLOR(aLista[6])
           cPantalla := SAVESCREEN(aLista[1], aLista[2],;
               aLista[3], aLista[4])
           @ aLista[1], aLista[2] TO aLista[3], aLista[4] DOUBLE
           nSeleccion := ACHOICE(++aLista[1], ++aLista[2],;
              --aLista[3], --aLista[4], aLista[5])
           SETCOLOR(cAnteriorColor)
           RESTSCREEN(--aLista[1], --aLista[2], ++aLista[3],;
               ++aLista[4], cPantalla)
           RETURN nSeleccion

 Ficheros   La biblioteca asociada es EXTEND.LIB.

 To download this example - click here.

See Also: RESTORE RESTORE SCREEN* SAVE SAVESCREEN()