SAVESCREEN()
 Guarda una parte de la pantalla para su posterior visualización
------------------------------------------------------------------------------
 Sintaxis

     SAVESCREEN([<nSup>], [<nIzq>],
        [<nInf>], [<nDer>]) --> cPantalla

 Argumentos

     <nSup>, <nIzq>, <nInf> y <nDer> definen las coordenadas
     de la parte de la pantalla que va a guardarse. Si <nInf> o <nDer> son
     mayores que MAXROW() o MAXCOL(), la pantalla se recorta. Si no se
     especifican coordenadas, se guarda toda la pantalla (es decir, desde
     0,0 hasta MAXROW(), MAXCOL()).

 Devuelve

     SAVESCREEN() devuelve la zona especificada de la pantalla como una
     cadena de caracteres.

 Descripción

     SAVESCREEN() es una función de pantalla que guarda una zona de la
     pantalla en una variable de cualquier clase de almacenamiento,
     incluyendo variables de campo. Más adelante, puede volver a mostrar la
     imagen de pantalla guardada, en la misma posición o en otra nueva,
     utilizando RESTSCREEN( ). Normalmente, las zonas de pantalla se
     almacenan y recuperan cuando se utiliza una rutina de menú emergente o
     se arrastra un objeto de pantalla.

     ¡Advertencia!  SAVE SCREEN, RESTORE SCREEN, SAVESCREEN() y
     RESTSCREEN() sólo deben utilizarse con  el controlador de pantalla por
     defecto (mapa de memoria del IBM-PC). Es posible que otros
     controladores de pantalla no admitan las operaciones de archivo y
     recuperación de pantallas.

 Ejemplos

      La siguiente función definida por el usuario crea un menú
        emergente que aparece en pantalla utilizando ACHOICE() con
        SAVESCREEN() y RESTSCREEN(), devolviendo la selección de la matriz
        de opciones:

        FUNCTION MenuEmergente( nSup, nIzq, nInf, nDer, ;
                        aElementos, cColor )
        LOCAL cPantalla, nOpcion, cUltColor := ;
              SETCOLOR(cColor)
           //
           cPantalla:= SAVESCREEN(nSup, nIzq, nInf, nDer)
           @ nSup, nIzq TO nInf, nDer DOUBLE
           //
           nOpcion:= ACHOICE(++nSup, ++nIzq, ;
                         --nInf, --nDer, aElementos)
           //
           RESTSCREEN(--nSup, --nIzq, ++nInf, ++nDer, ;
                         cPantalla)
           SETCOLOR(cUltColor)
           RETURN nOpcion

 Ficheros   La biblioteca asociada es EXTEND.LIB.

 To download this example - click here.

See Also: RESTSCREEN()