SETCANCEL()
 Activa o desactiva Alt+C y Ctrl+Inter como teclas de finalización de
 programa
------------------------------------------------------------------------------
 Sintaxis

     SETCANCEL([<lConmutar>]) --> lAjusteActual

 Argumentos

     <lConmutar> modifica la disponibilidad de Alt+C y Ctrl+Inter como
     teclas de finalización. El valor verdadero (.T.) permite la utilización
     de ambas combinaciones de teclas para finalizar una aplicación y el
     valor falso (.F.) las desactiva. El valor por defecto es verdadero
     (.T.).

 Devuelve

     SETCANCEL() devuelve el ajuste actual como valor lógico.

 Descripción

     SETCANCEL() es una función de teclado que activa o desactiva el estado
     de las teclas de finalización Alt+C y Ctrl+Inter, e informa sobre el
     estado actual de SETCANCEL().

     Tenga en cuenta que si Alt+C o Ctrl+Inter se redefinen con SET KEY,
     esta nueva definición tiene prioridad aunque SETCANCEL() tenga el
     valor verdadero (.T.).

     ¡Advertencia!  Cuando se establece SETCANCEL() con el valor falso
     (.F.), el usuario no puede finalizar un programa fuera de control a
     menos que se le proporcione un mecanismo de salida alternativo.

 Ejemplos

      Este ejemplo ofrece una vía de salida a partir de un estado de
        espera con la función SETCANCEL() desactivada:

        #define K_ALTC   302
        //
        SETCANCEL(.F.)               // Desactivar teclas de finalización
        SET KEY K_ALTC TO AltC       // Redefinir Alt+C
        .
        . <sentencias>
        .
        RETURN
        FUNCTION AltC

           LOCAL cPantalla, nOpcion, cUltimoColor := ;
                  SETCOLOR("W/B, N/G")
           //
           SAVE SCREEN TO cPantalla
           @ 6, 20 CLEAR TO 9, 58
           @ 6, 20 TO 9, 58 DOUBLE
           @ 7, 26 SAY "Alt+C: ¿Desea salir?"
           @ 8, 35 PROMPT " Sí "
           @ 8, 41 PROMPT " No "
           MENU TO nOpcion
           SETCOLOR(cUltimoColor)
           RESTORE SCREEN FROM cPantalla
           //
           IF nOpcion = 1
              QUIT
           ENDIF
           //
           RETURN NIL

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: SET ESCAPE SET KEY SETKEY()