UPPER()
 Convierte todas las minúsculas en mayúsculas
------------------------------------------------------------------------------
 Sintaxis

     UPPER(<cCadena>) --> cCadenaMayús

 Argumentos

     <cCadena> es la cadena de caracteres que se va a convertir.

 Devuelve

     UPPER() devuelve una copia de <cCadena> con todos los caracteres
     alfabéticos transformados en mayúsculas. Los restantes caracteres
     permanecen inalterados como en la cadena original.

 Descripción

     UPPER() es una función de caracteres que convierte cadenas en
     minúsculas y mixtas en cadenas en mayúsculas. Está relacionada con
     LOWER() que convierte cadenas en mayúsculas y mixtas en cadenas en
     minúsculas. UPPER() está relacionada también con las funciones
     ISUPPER() y ISLOWER(), que determinan si una cadena comienza con una
     letra minúscula o mayúscula.

     UPPER() se utiliza normalmente para formatear cadenas de caracteres con
     fines de visualización. También puede utilizarse para homogeneizar
     cadenas en comparaciones que no diferencian mayúsculas y minúsculas o
     para ordenación con INDEX.

 Ejemplos

      Este ejemplo muestra el resultado de UPPER():

        ? UPPER("una cadena")        // Resultado: UNA CADENA
        ? UPPER("123 carac = <>")    // Resultado: 123 CARAC = <>

      Este ejemplo utiliza UPPER() como parte de una condición
        independiente de mayúsculas y minúsculas:

        USE Cliente INDEX NombreCliente NEW
        LIST NombreCliente FOR "KATE" $ UPPER(Cliente)

      UPPER() es útil también para crear expresiones clave de
        índices, independientes de mayúsculas y minúsculas:

        USE Cliente NEW
        INDEX ON UPPER(Apellido) TO Apellido

      A continuación, puede utilizar esta expresión para buscar Clientes:

        MEMVAR->Apellido = SPACE(15)
        @ 10, 10 GET MEMVAR->Apellido
        READ
        SEEK UPPER(MEMVAR->Apellido)

 Ficheros   La biblioteca asociada es CLIPPER.LIB.