ALERT()
 Muestra en pantalla un panel de diálogo modal sencillo
------------------------------------------------------------------------------
 Sintaxis

     ALERT( <cMensaje>, [<aOpciones>] ) --> nSelección

 Argumentos

     <cMensaje> es el texto del mensaje, mostrado y centrado en el
     cuadro de advertencia. Si el mensaje contiene uno o más signos de punto
     y coma, el texto que va detrás de estos signos se centra en las líneas
     siguientes del panel de diálogo.

     <aOpciones> define una lista de hasta cuatro posibles respuestas al
     panel de diálogo.

 Devuelve

     ALERT() devuelve un valor numérico que indica la opción escogida. Si se
     pulsa la tecla Esc, el valor devuelto es cero.

 Descripción

     La función ALERT() crea un panel de diálogo modal sencillo. Es útil
     para manejadores de error y otras funciones de "pausa". El usuario
     puede responder moviendo una barra resaltada y pulsando las teclas
     Intro o Barra espaciadora, o pulsando la tecla correspondiente a la
     primera letra de la opción. Si no se especifica <aOpciones>, sólo
     aparece la opción "OK" o "Aceptar".

     ALERT() es sensible a la utilización del sistema de entrada/salida de
     pantalla completa de CA-Clipper. Si no se utiliza el sistema de
     pantalla completa, ALERT() utiliza la entrada/salida estándar y muestra
     el mensaje y las opciones en estilo de teleimpresora (es decir, 80
     columnas, sin saltos de línea automáticos y cada línea terminada con un
     retorno de carro/salto de línea).

 Ejemplos

      El ejemplo de la página siguiente muestra la utilización de un
        panel de advertencia. Primero se define la matriz de las opciones,
        la función ALERT() recoge la selección del usuario y, finalmente,
        ésta se procesa con una estructura de control DO CASE...ENDCASE:

        #define AL_SAVE                1
        #define AL_CANCEL              2
        #define AL_CONT                3

        // Define una matriz de opciones
        aOpciones := {"Salvar", "No Salvar", "Continuar"}

        // Muestra el panel de diálogo y recoge la
        // selección del usuario
        nSeleccion := ALERT("El fichero ha sido modificado...", aOpciones)

        // Procesa la selección del usuario
        DO CASE
        CASE nSeleccion == AL_SAVE
           ? "Salvar"
        CASE nSeleccion == AL_CANCEL
           ? "No Salvar"
        CASE nSeleccion == AL_CONT
           ? "Continuar"
        OTHERWISE
           ? "Escape"
        ENDCASE
        //
        RETURN

 Ficheros   La biblioteca asociada es LLIBG.LIB.

 To download this example - click here.

See Also: @...PROMPT MENU TO