@...GET RADIOGROUP
 Crea un objeto Get consistente en un grupo de botones de opción y lo muestra
 en pantalla
------------------------------------------------------------------------------
 Sintaxis

     @ <nSup>, <nIzq>, <nInf>, <nDer>
        GET <nVar|cVar>
        RADIOGROUP <aGrupo>
           [CAPTION <cTítulo>]
           [MESSAGE <cMensaje>]
           [COLOR <cCadenaColor>]
           [FOCUS] <fbloque>(
           [WHEN <lCondiciónPrevia>]
           [VALID <lCondiciónPosterior>]
           [SEND <mensaje>]
           [GUISEND <mensajeGUI>]

 Argumentos

     <nSup>, <nIzq>, <nInf> y <nDer> especifican las
     coordenadas de pantalla para el grupo de botones de opción y su título.
     No se visualizarán los objetos que excedan de los límites de la
     pantalla.

     GET <nVar|cVar> especifica el nombre de la variable asociada al
     mandato GET. Su valor indica qué botón de opción del grupo está
     seleccionado (si hay alguno). Si la variable es numérica contendrá la
     posición del botón seleccionado. Un valor  0 indica que no hay ningún
     botón seleccionado. Si el valor es una cadena de caracteres,
     contendrá los datos o el texto asociado con el botón seleccionado. Si
     la cadena de caracteres no se corresponde con ningún elemento de la
     lista, entonces no hay ningún botón seleccionado.

     RADIOGROUP <aGrupo> especifica una matriz de objetos RadioButto.

     CAPTION <cTítulo> especifica una cadena de caracteres que describe
     en pantalla, de forma concisa, el significado del Get. Existen dos
     diferencias entre CAPTION y SAY. La primera es que el título aparece
     cada vez que el GET se muestra en pantalla. La segunda es que el
     título y su posición en pantalla se almacenan en el objeto Get. Esto
     permite que el GET pueda recibir la entrada del usuario al hacer clic
     en el título con el botón izquierdo del ratón. Por defecto, el título
     aparece en la esquina superior izquierda del GET. Es posible utilizar
     las variables capRow y capCol del objeto Get para modificar la posición
     en pantalla del título.

     Si en la cadena de caracteres del título está presente el carácter &,
     el carácter que le sigue se utiliza como tecla aceleradora del grupo de
     botones de opción. La tecla aceleradora es un método rápido para pasar
     el foco de entrada al grupo de botones. En las teclas aceleradoras no
     se distingue entre mayúsculas y minúsculas.

     MESSAGE <cMensaje> especifica la cadena de caracteres que aparece
     en la barra de la línea de estado del sistema  Get cuando el GET tiene
     el foco de entrada. Normalmente, contiene una breve  descripción o una
     respuesta al usuario acerca del GET. Consulte el mandato READ para
     obtener detalles del funcionamiento de la barra de estado del sistema
     Get.

     COLOR <cCadenaColor> define los colores seleccionados para el grupo
     de botones de opción. <cCadenaColor> es una expresión de caracteres que
     contiene tres parámetros de color.

     Atributos de color del grupo de botones de opción
     ------------------------------------------------------------------------
     Posición          Se aplica a                      Valor por defecto
     en colorSpec                                       (parámetros de color
                                                        del sistema)
     ------------------------------------------------------------------------
     1                  El borde del grupo de botones        Borde
                        de opción
     2                  El título del grupo de botones       Estándar
                        de opción
     3                  La tecla aceleradora del             Fondo
                        título del grupo de botones
                        de opción
     ------------------------------------------------------------------------

     FOCUS <fbloque> especifica un bloque de código que se evalúa cada
     vez que el grupo de botones recibe el foco. El bloque de código no
     tiene argumentos implícitos. La variable de instancia
     RadioGroup:hasFocus se utiliza para determinar si el grupo de botones
     de opción tiene el foco.

     WHEN <lCondiciónPrevia> especifica una expresión que debe
     satisfacerse antes de que el cursor entre en el GET durante un mandato
     READ. La expresión puede ser, opcionalmente, un bloque de código. El
     objeto Get se pasa como parámetro al bloque de código.

     VALID <lCondiciónPosterior> especifica una expresión que debe
     satisfacerse antes de que el cursor pueda salir del GET durante un
     mandato READ. La expresión puede ser, opcionalmente, un bloque de
     código. El objeto Get se pasa como parámetro al bloque de código.

     Nota:  No existe una cláusula STATE para el mandato @...GET
     RADIOGROUP. En su lugar,  cada botón de opción del grupo tiene su
     propia variable de instancia sBlock. Si desea más detalles, consulte
     sBlock en la descripción de la clase RadioButto.

     SEND <mensaje> envía el mensaje especificado al objeto Get.
     <mensaje> se envía antes de la visualización del mandato GET. Es
     posible enviar cualquier mensaje, incluidas las llamadas a métodos y
     asignaciones de variables de instancia. Las llamadas a métodos deben
     incluir paréntesis aunque no se pasen argumentos.

     GUISEND <mensajeGUI> se puede utilizar para enviar un mensaje (por
     ejemplo, el método display()) a un objeto GUI. Los objetos GUI en
     CA-Clipper son cuadros de selección, cuadros de lista, botones y grupos
     de botones de opción. Para enviar un mensaje a un objeto que no sea
     GUI, por ejemplo objetos Get y TBrowse, se utiliza la cláusula SEND.

 Ejemplos

      Este ejemplo muestra cómo añadir un grupo de botones de opción
        en una pantalla de entrada de datos. Se utiliza un método de
        selección basado en la posición:

        nColor := 1 // por defecto el primer elemento.
        aGrupo := ARRAY( 3 )
        aGrupo[ 1 ] := RadioButto( 6, 22, "&Rojo" )
        aGrupo[ 2 ] := RadioButto( 7, 22, "&Verde" )
        aGrupo[ 3 ] := RadioButto( 8, 22, "&Azul" )
        @ 5, 20, 9, 40 GET nColor RADIOGROUP aGrupo

       La variable nColor devuelve una posición, en este caso 1, 2 ó 3.

      Este ejemplo muestra la utilización de un grupo de botones de
        opción que emplean un método de selección basado en los datos:

        cColor := "R" // por defecto se estable a rojo.
        aGrupo := ARRAY( 3 )
        aGrupo[ 1 ] := RadioButto( 6, 22, "&Rojo", "R" )
        aGrupo[ 2 ] := RadioButto( 7, 22, "&Verde", "V" )
        aGrupo[ 3 ] := RadioButto( 8, 22, "&Azul", "A" )
        @ 5, 15, 9, 40 GET cColor RADIOGROUP aGrupo

       La variable nColor devuelve un dato, en este caso "R", "V" o "A".

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: Get RadioButto RadioGroup READ