@...PROMPT
 Dibuja un elemento de menú y le asocia un mensaje
------------------------------------------------------------------------------
 Sintaxis

     @ <nFila>, <nColumna> PROMPT <cElemMenú>
        [MESSAGE <cExpresión>]

 Argumentos

     <nFila> y <nColumna> son las coordenadas de fila y columna del
     elemento de menú mostrado. Los valores de <nFila> están comprendidos
     entre cero y MAXROW(), y los valores de <nColumna> entre cero y
     MAXCOL().

     PROMPT <cElemMenú> es la cadena de caracteres del elemento del menú
     que se va a mostrar.

     MESSAGE <cExpresión> define el mensaje que se muestra cuando se
     selecciona el elemento de menú. Puede utilizarse opcionalmente un
     bloque de código que se evalúe como una expresión de caracteres.

 Descripción

     @...PROMPT es la parte del sistema de barras de menús de CA-Clipper
     encargada de la visualización. Cada mandato @...PROMPT dibuja un
     elemento de menú en el color estándar actual y un mensaje asociado que
     se muestra en la línea especificada en SET MESSAGE. El menú se debe
     invocar después con el mandato MENU TO. Los elementos de menú se pueden
     especificar en cualquier orden y con cualquier definición de posiciones
     de fila y columna. MENU TO, no obstante, recorre la lista actual de
     elementos de menú en el orden en que están definidos. Puede definir
     hasta un máximo de 4.096 elementos en cada menú.

     Después de cada mandato  @...PROMPT, el cursor se encuentra una columna
     a la derecha del último carácter del elemento de menú y ROW() y COL()
     se actualizan para reflejar la nueva posición del cursor. Esto permite
     utilizar estas funciones para especificar posiciones de elementos de
     menú consecutivas al primer elemento dibujado. Consulte el ejemplo
     siguiente.

 Ejemplos

      Este ejemplo muestra un menú con los mensajes asociados
        mostrados en la línea siguiente. Cuando el usuario pulsa Intro, la
        posición del elemento de la lista se asigna  a la variable nOpcion:

        LOCAL nOpcion := 1
        SET WRAP ON
        SET MESSAGE TO 2
        @ 1, 3 PROMPT "Fichero" MESSAGE "Acceso a ficheros de datos"
        @ ROW(), COL() + 2 PROMPT "Editar" ;
           MESSAGE "Editar registro actual"
        MENU TO nOpcion

      Este ejemplo muestra cómo pasar a la cláusula MESSAGE un
        bloque de código que invoca una función definida por el usuario que
        muestra un mensaje en un color diferente:

        SET COLOR TO gr+/b,r+/n
        SET MESSAGE TO 23    // Esto es necesario.
        CLEAR SCREEN

        @ 3,4 PROMPT "uno "  MESSAGE {||UDF("Mensaje Uno  ")}
        @ 4,4 PROMPT "dos "  MESSAGE {||UDF("Mensaje Dos  ")}
        @ 5,4 PROMPT "tres"  MESSAGE {||UDF("Mensaje Tres ")}

        MENU TO prueba

        FUNCTION UDF(cParm)
        cColorAnterior := SETCOLOR("b+/n")
        @ 22,1 SAY cParm          // Debe ser una fila diferente de
                                  // la SET MESSAGE TO nFila
        SETCOLOR(cColorAnterior)
        RETURN ""                 // Cadena de caracteres que debe
                                  // devolverse

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: ACHOICE() MENU TO SET MESSAGE SET WRAP* SETCOLOR()