CONTINUE
 Reanuda un LOCATE pendiente
------------------------------------------------------------------------------
 Sintaxis

     CONTINUE

 Descripción

     CONTINUE es un mandato de base de datos que busca, desde la posición
     actual, el siguiente registro que cumple la condición LOCATE más
     reciente que se haya ejecutado en el área de trabajo actual. Finaliza
     cuando se encuentra un registro que la cumpla o el final del fichero.
     Si CONTINUE tiene éxito, el registro coincidente pasa a ser el
     registro actual y FOUND() devuelve verdadero (.T.); en caso contrario,
     FOUND() devuelve falso (.F.).

     Todas las áreas de trabajo pueden tener una condición LOCATE activa. En
     CA-Clipper, la condición LOCATE permanece pendiente hasta que se
     especifica una nueva. Ningún otro mandato puede liberar esta
     condición.

 Notas

     ■ Ambito y condición WHILE: Recuerde que se ignoran el ámbito y la
        condición WHILE de la sentencia LOCATE inicial; sólo se utiliza la
        condición FOR con CONTINUE. Si utiliza una sentencia LOCATE con una
        condición WHILE y desea continuar la búsqueda de un registro
        coincidente, utilice SKIP y luego repita la sentencia LOCATE
        original añadiendo REST como ámbito.

 Ejemplos

      Este ejemplo examina los registros de Ventas.dbf para buscar
        un vendedor concreto y muestra en pantalla un importe de ventas
        total acumulado:

        LOCAL nTotalAct := 0
        USE Ventas NEW
        LOCATE FOR Ventas->Vendedor = "1002"
        DO WHILE FOUND()
           ? Ventas->NombreVend, nTotalAct += Ventas->Importe
           CONTINUE
        ENDDO

      El ejemplo siguiente muestra el método para continuar si el
        ámbito del LOCATE pendiente contiene una condición WHILE:

        LOCAL nTotalAct := 0
        USE Ventas INDEX Vendedor NEW
        SEEK "1002"
        LOCATE REST WHILE Ventas->Vendedor = "1002";
              FOR Ventas->Importe > 5000
        DO WHILE FOUND()
           ? Ventas->NombreVend, nTotalAct+= Ventas->Importe
           SKIP
           LOCATE REST WHILE Ventas->Vendedor = "1002";
              FOR Ventas->Importe > 5000
        ENDDO

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: EOF() FOUND() LOCATE SEEK