COPY STRUCTURE
 Copia la estructura .dbf actual en un nuevo fichero de base de datos (.dbf)
------------------------------------------------------------------------------
 Sintaxis

     COPY STRUCTURE [FIELDS <idLista campos>]
        TO <xcBasedeDatos>

 Argumentos

     FIELDS <idLista campos> define el grupo de campos que se van a
     copiar en la nueva estructura de base de datos en el orden
     especificado. El valor por defecto es todos los campos.

     TO <xcBasedeDatos> es el nombre del fichero de base de datos
     objeto. Puede especificarse como nombre de fichero de base de datos en
     forma literal o como expresión de caracteres encerrada entre
     paréntesis. La extensión por defecto es .dbf, a menos que se
     especifique otra.

 Descripción

     COPY STRUCTURE es un mandato de base de datos que crea un fichero de
     base de datos vacío con las definiciones de campo del fichero actual.
     Si ya existe <xcBasedeDatos>, se sobreescribe.

     COPY STRUCTURE crea estructuras vacías que pueden utilizarse para
     archivar registros del fichero actual de base de datos o para crear un
     fichero de base de datos temporal para introducción de datos.

 Ejemplos

      En este ejemplo, COPY STRUCTURE crea un fichero temporal. Una
        vez que el usuario ha introducido los datos en este fichero, el
        fichero de base de datos principal se actualiza con la nueva
        información:

        USE Ventas NEW
        COPY STRUCTURE TO Temp
        USE Temp NEW
        lMas := .T.
        DO WHILE lMas
           APPEND BLANK
           @ 10, 10 GET Temp->Vendedor
           @ 11, 11 GET Temp->Importe
           READ
           IF UPDATED()
              SELECT Ventas
              APPEND BLANK
              REPLACE Ventas->Vendedor WITH Temp->Vendedor
              REPLACE Ventas->Importe WITH Temp->Importe
              SELECT Temp
              ZAP
           ELSE
              lMas := .F.
           ENDIF
        ENDDO
        CLOSE DATABASES

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: COPY STRU EXTE CREATE