MENU TO
 Ejecuta un menú de barra luminosa con las opciones definidas mediante el
 mandato @... PROMPT
------------------------------------------------------------------------------
 Sintaxis

     MENU TO <idVar>

 Argumentos

     <idVar> es el nombre de la variable a la que se asigna el resultado
     de la selección de menú. Si la variable especificada no está visible o
     no existe, se crea una variable privada y se le asigna el resultado.

 Descripción

     MENU TO es el mecanismo de selección del sistema de menús de barra
     luminosa de CA-Clipper. Antes de utilizar MENU TO, deben haberse
     definido las opciones del menú y sus mensajes asociados con una serie
     de mandatos @...PROMPT. Luego, puede activarse el menú con MENU TO
     <idVar>. Si <idVar> no existe o no está visible, MENU TO crea una
     variable privada y sitúa la zona resaltada en el primer elemento del
     menú. Si <idVar> ya existe, su valor inicial determina el primer
     elemento de menú resaltado.

 Notas

     ■ Color: Los elementos de menú se dibujan en el color estándar y
        el elemento de menú resaltado aparece en el color resaltado.

     ■ Desplazamiento y selección: Las teclas de flecha desplazan la
        zona resaltada al elemento de menú siguiente o anterior. A medida
        que se resaltan los elementos de menú, los mensajes asociados se
        muestran en la fila especificada con SET MESSAGE. Si se ha
        especificado SET WRAP ON, al pulsar la flecha Arriba en el primer
        elemento del menú la zona resaltada pasa al último elemento del
        menú. De igual forma, al pulsar la flecha Abajo en el último
        elemento de menú la zona resaltada pasa al primer elemento.

        Para seleccionar un elemento, pulse Intro o el primer carácter del
        elemento de menú. MENU TO devuelve la posición del elemento
        seleccionado como valor numérico en la variable de memoria
        especificada. Si se pulsa Esc, se anula la selección de menú y se
        devuelve cero. La tabla siguiente resume las teclas activas con MENU
        TO.

     ■ Procedimientos SET KEY: Puede anidarse un mandato MENU TO
        mediante un procedimiento SET KEY invocado dentro de un menú sin
        eliminar los PROMPT pendientes.

        Teclas activas de MENU TO
        ---------------------------------------------------------------------
        Tecla                Acción
        ---------------------------------------------------------------------
        Flecha Arriba        Se desplaza al elemento de menú anterior
        Flecha Abajo         Se desplaza al elemento de menú siguiente
        Inicio               Se desplaza al primer elemento de menú
        Fin                  Se desplaza al último elemento de menú
        Flecha Izquierda     Se desplaza al elemento de menú anterior
        Flecha Derecha       Se desplaza al elemento de menú siguiente
        RePág                Selecciona un elemento de menú, devolviendo
                             la posición
        AvPág                Selecciona un elemento de menú, y devuelve
                             su posición
        Intro                Selecciona un elemento de menú, y devuelve
                             su posición
        Esc                  Anula la selección, devolviendo cero
        Primera Letra        Selecciona el primer elemento de menú que
                             empiece por la misma letra, devolviendo
                             su posición
        ---------------------------------------------------------------------

 Ejemplos

      Este ejemplo crea un menú de barra vertical sencillo, con
        mensajes centrados en la línea 23. Al invocarlo, la zona resaltada
        aparece, por defecto, en el segundo elemento de menú, basándose en
        el valor inicial de nSeleccion:

        LOCAL nSeleccion := 2
        SET WRAP ON
        SET MESSAGE TO 23 CENTER
        @ 6, 10 PROMPT "Añadir" MESSAGE "Nueva Cuenta"
        @ 7, 10 PROMPT "Editar" MESSAGE "Cambiar Cuenta"
        @ 9, 10 PROMPT "Salir" MESSAGE "Volver al DOS"
        MENU TO nSeleccion
        //
        DO CASE
        CASE nSeleccion = 0
           QUIT
        CASE nSeleccion = 1
           NuevaCuenta()
        CASE nSeleccion = 2
           CambioCuenta()
        CASE nSeleccion = 3
           QUIT
        ENDCASE
        RETURN

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: @...PROMPT ACHOICE() SET MESSAGE SET WRAP*