RUN
 Ejecuta un programa o mandato del DOS
------------------------------------------------------------------------------
 Sintaxis

     RUN | !* <xcLíneaMandato>

 Argumentos

     <xcLíneaMandato> es cualquier programa ejecutable, incluyendo
     COMMAND.COM y mandatos internos del DOS. Puede especificarse como
     cadena literal o como expresión de caracteres encerrada entre
     paréntesis.

 Descripción

     RUN ejecuta un programa o mandato del DOS desde una aplicación
     compilada. Cuando se ejecuta un programa del DOS, CA-Clipper ejecuta
     otra copia de COMMAND.COM, pasando al mismo tiempo la línea de mandatos
     del DOS. Esto tiene dos implicaciones: en primer lugar, debe haber
     suficiente memoria para COMMAND.COM (5K para el DOS 6.2) y para el
     programa que se desea ejecutar y, en segundo lugar, debe poder
     accederse a COMMAND.COM en la vía especificada por COMSPEC (por
     defecto, es el directorio raíz del disco de arranque del DOS). Si
     COMMAND.COM no está situado en este disco o se ha cambiado de disco,
     debe indicar mediante la variable de entorno COMSPEC la nueva posición
     antes de ejecutar la aplicación de CA-Clipper. Recuerde que SET DEFAULT
     y SET PATH no afectan al mandato RUN.

     La forma ! del mandato RUN se incluye sólo por razones de
     compatibilidad, por lo que su utilización no es recomendable.

     ¡Advertencia! No ejecute programas residentes en memoria desde
     CA-Clipper, ya que puede perder memoria cuando el control vuelva a su
     programa de aplicación.

 Ejemplos

      Este ejemplo utiliza RUN con MEMOREAD() y MEMOWRIT() para crear una
        función definida por el usuario que invoca un editor de texto para
        el campo memo actual:

        lExito = EditorMemo("Edit", "Notas")
        RETURN

        FUNCTION EditorMemo(cEditor, cCampMemo)
           IF MEMOWRIT("EditClip.tmp", &cCampMemo.)
              RUN (cEditor + " EditClip.tmp")
              REPLACE &cCampMemo. WITH MEMOREAD("EditClip.tmp")
              ERASE EditClip.tmp
              RETURN .T.
           ELSE
              RETURN .F.
           ENDIF

      Una de las opciones que puede ofrecer a sus usuarios es un
        acceso directo al DOS. Esto se hace de la siguiente manera:

        RUN COMMAND

        Para facilitar al usuario la vuelta al programa de aplicación,
        cambie el indicativo del DOS en el fichero de trabajos por lotes de
        la aplicación, como se indica a continuación:

        REM Fichero por Lotes de la Aplicación

        ECHO OFF
        PROMPT Acceso al DOS: Escriba EXIT para volver a ;
                la aplicacion$_$p$g
        <su programa de aplicación>
        PROMPT $p$g

        A continuación, indique al usuario que ejecute el fichero de
        trabajos por lotes de la aplicación en lugar del fichero .EXE de la
        misma.

 Ficheros   La biblioteca asociada es CLIPPER.LIB.