SET COLOR*
 Define los colores de la pantalla
------------------------------------------------------------------------------
 Sintaxis

     SET COLOR | COLOUR TO [[<estándar>]
        [,<mejorado>] [,<borde>] [,<fondo>]
        [,<noseleccionado>]] | (<cCadenaColor>)

 Argumentos

     <estándar> es el color que utlilizan todos los mandatos y funciones
     de consola, pantalla completa e interfaz cuando escriben en la
     pantalla. Esto incluye mandatos como @...PROMPT, @...SAY y ?, y
     funciones como ACHOICE(), DBEDIT() y MEMOEDIT().

     <mejorado> es el color en que se muestran las visualizaciones
     resaltadas. Esto incluye los elementos resaltados de GET con INTENSITY
     ON, MENU TO, DEBEDIT() y ACHOICE().

     <borde> es el color en que se muestra el área que rodea a la
     pantalla y en la cual no puede escribirse.

     <fondo> no está admitido actualmente por ningún ordenador con
     controladores de Computer Associates. Se ofrece sólo por motivos de
     compatibilidad.

     <noseleccionado> es un par de colores en que se muestran los GET
     sin foco de entrada y las opciones de menú no disponibles.

     <cCadenaColor> es una cadena de caracteres, entre paréntesis, que
     contiene la configuración de color. Esta utilidad le permite
     especificar los ajustes de color como una expresión en lugar de como
     una cadena literal o variable de macro.

     SET COLOR TO sin argumentos restablece los colores por defecto a W/N,
      N/W, N, N, N/W.

 Descripción

     SET COLOR, mandato sinónimo de la función SETCOLOR(), define los
     colores para las futuras acciones de dibujo en pantalla. Cada mandato
     SET COLOR especifica una lista de valores de colores para los cinco
     tipos de actividad de dibujo en pantalla. Cada ajuste o valor es un par
     de colores de primer plano y fondo separados por un carácter de barra
     (/). El color del primer plano define el color de los caracteres que
     se muestran en pantalla. El fondo viene definido por el color que
     aparece detrás del carácter de barra ("/"). Los espacios y caracteres
     que no se muestran aparecen sólo como fondo.

     Además del color, un valor de primer plano puede tener un atributo:
     intensidad alta o parpadeo. Con una pantalla monocroma, la intensidad
     alta aumenta el brillo del texto. Con un pantalla en color, este
     atributo modifica la tonalidad del color especificado convirtiéndolo en
     otro diferente. Por ejemplo, N muestra el texto de primer plano en
     negro mientras que N+ lo muestra en gris. La intensidad alta se indica
     mediante "+". El atributo de parpadeo hace que el texto de primer plano
     aparezca y desaparezca a intervalos rápidos. El parpadeo se indica
     mediante "*". El caracter de atributo puede especificarse en cualquier
     punto del color, pero siempre afecta al color de primer plano
     independientemente de donde se incorpore.

     Cada color puede especificarse usando una letra o un número, pero los
     números y letras no pueden mezclarse en un mismo parámetro. Tenga en
     cuenta que los números se proporcionan por motivos de compatibilidad y
     que su utilización no es recomendable.

     Todos los valores son opcionales. Si se ignora uno de ellos, se
     conserva su valor previo quedando establecidos sólo los valores nuevos.
     Si se ignora un color de primer plano o de fondo dentro de un ajuste,
     el color se define como negro.

     Pueden utilizarse los siguientes colores:

     Tabla de colores
     ------------------------------------------------------------------------
     Color           Letra        Número     Monocromo
     ------------------------------------------------------------------------
     Negro           N, Espacio   0          Negro
     Azul            B            1          Subrayado
     Verde           G            2          Blanco
     Cian            BG           3          Blanco
     Rojo            R            4          Blanco
     Magenta         RB           5          Blanco
     Marrón          GR           6          Blanco
     Blanco          W            7          Blanco
     Gris            N+           8          Negro
     Azul intenso    B+           9          Subr. intenso
     Verde intenso   G+           10         Blanco intenso
     Cian intenso    BG+          11         Blanco intenso
     Rojo intenso    R+           12         Blanco intenso
     Magenta intenso RB+          13         Blanco intenso
     Amarillo        GR+          14         Blanco intenso
     Blanco intenso  W+           15         Blanco intenso
     Negro           U                       Subrayado
     Vídeo inverso   I                       Vídeo inverso
     En blanco       X                       En blanco
     ------------------------------------------------------------------------

     SET COLOR es un mandato de compatibilidad y su utilización no es
     recomendable. Lo sustituye la función SETCOLOR() que puede devolver el
     color actual así como establecer uno nuevo.

 Notas

     ■ Monitores monocromos: Los monitores monocromos no admiten color.
        Sin embargo, CA-Clipper utiliza los atributos monocromos de vídeo
        inverso (I) y subrayado (U).

     ■ Controladores de pantalla: Posiblemente el uso de SET COLOR TO
        con números sólo esté admitido por el controlador de pantalla por defecto.

 Ejemplos

      Este ejemplo utiliza el valor que no seleccionado para que el
        GET actual sea rojo sobre blanco mientras el resto se muestre en
        negro sobre blanco:

        cColor:= "W/N,R/W,,,N/W"
        SET COLOR TO (cColor)
        cUno := cDos := SPACE(10)
        @ 1, 1 SAY "Introducir Uno: " GET cUno
        @ 2, 1 SAY "Introducir Dos: " GET cDos
        READ

      En este ejemplo, una función definida por el usuario obtiene
        una contraseña (clave de acceso) del usuario utilizando el color
        resaltado en blanco (X) para ocultarla a medida que el usuario la
        escribe:

        IF !DialogClaveacceso(12, 13, "W+/N", "FUNSUN", 3)
           ? "Su clave de acceso ha fallado"
           QUIT
        ENDIF

        FUNCTION DialogClaveacceso( nFila, nCol, ;
               cEstandar, cClaveacceso, nIntentos )
           LOCAL nRecuento := 1, cColor := SETCOLOR()
           SET COLOR TO (cEstandar + ", X")             // Entrada en blanco
           //
           DO WHILE nRecuento < nIntentos
              cEntradaUsuario:= SPACE(6)
              @ nFila, nCol SAY  "Introducir clave de acceso: " GET ;
                        cEntradaUsuario
              READ
              //
              IF LASTKEY() == 27
                  SET COLOR TO (cColor)
                  RETURN .F.

              ELSEIF cEntradaUsuario == cClaveacceso
                  SET COLOR TO (cColor)
                  RETURN .T.
              ELSE
                  nRecuento++
              ENDIF
           ENDDO
           //
           SET COLOR TO (cColor)
           RETURN .F.

 Ficheros   La biblioteca asociada es CLIPPER.LIB.

 To download this example - click here.

See Also: @...GET @...SAY ISCOLOR() SETCOLOR() SETBLINK()