CTOD()
 Converte uma cadeia de caracteres em uma data correspondente
------------------------------------------------------------------------------

 Sintaxe

     CTOD(<cData>) --> dData

 Argumentos

     <cData> é uma cadeia de caracteres que contém números representando
     o mês, dia, e ano separados por qualquer outro caractere que nao um
     número.  Os dígitos do mês, dia, e ano devem ser especificados de
     acordo com o formato indicado pelo SET DATE.  Se os dígitos do século
     nao sao especificados, o século é determinado pelas regras do SET
     EPOCH.

 Retorno

     CTOD() retorna um dado do tipo data.  Se <cData> nao é uma data válida,
     CTOD() retorna uma data vazia.

 Descriçao

     CTOD() é uma funçao de conversao de caracteres que converte uma cadeia
     de caracteres em uma data.  Para inicializar uma data vazia para uma
     entrada de dados, especifique a <cData> como sendo uma cadeia de
     caracteres nula (""), SPACE(8), ou "  /  /  ".

     CTOD() é usado sempre que você precisar um dado literal do tipo data.
     Alguns exemplos sao:

       Inicializando uma variável para um valor do tipo data

       Especificando um literal do tipo data como sendo um argumento
        de uma cláusula RANGE de um @...GET

       Especificando um literal do tipo data a fim de realizar
        operaçoes aritméticas com esta

       Comparando o resultado de uma expressao do tipo data com um
        cadeia literal do mesmo tipo

       Efetuando REPLACE em um campo do tipo data com uma cadeia
        literal do mesmo tipo

     CTOD() é o inverso de DTOC() na qual converte um valor do tipo data
     para uma cadeia de caracteres no formato especificado pelo SET DATE e
     SET CENTURY.  DTOS() também converte um valor do tipo data para uma
     cadeia de caracteres na forma aaaammdd.

 Exemplos

       O exemplo seguinte utiliza CTOD() para inicializar duas
        variáveis do tipo data, usando uma no GET e a outra para a validaçao
        do RANGE:

        SET CENTURY ON
        dBegin = CTOD("01-26-1876")
        dCurrent = CTOD("")
        @ 10, 10 SAY "Digite a data:" GET dCurrent RANGE dBegin, DATE()
        READ

       Este exemplo utiliza CTOD() para criar um valor do tipo data
        dentro de uma condiçao FOR:

        USE Inventory NEW
        REPLACE ALL Inventory->Price WITH Inventory->Price * 1.1;
           FOR Inventory->InvDate < CTOD("10/10/90")

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: DATE() DTOC() DTOS() SET CENTURY SET DATE SET EPOCH