DBFILTER()
 Retorna a expressao de filtragem corrente na forma de cadeia de caracteres
------------------------------------------------------------------------------

 Sintaxe

     DBFILTER() --> cFiltro

 Retorno

     DBFILTER() retorna a condiçao de filtragem definida na área de trabalho
     corrente na forma de cadeia de caracteres.  Caso nenhum filtro tenha
     sido configurado (SET FILTER), a funçao DBFILTER() retornará um string
     nulo ("").

 Descriçao

     DBFILTER() é uma funçao que atua em arquivos de dados, e é utilizada
     para guardar e re-executar um filtro ativo através do retorno da
     expressao de filtragem na forma de cadeia de caracteres que pode ser
     mais tarde recompilada e executada utilizando o operador macro (&).
     Esta funçao opera de maneira similar às funçoes DBRELATION() e
     DBRSELECT() que sao utilizadas para guardar e re-executar a expressao
     de uniao de um relacionamento com uma área de trabalho.

     Desde que cada área de trabalho pode ter um filtro ativo, DBFILTER()
     pode retornar a expressao de filtragem de qualquer área de trabalho.
     Isto é feito através da referência da funçao DBFILTER() em uma
     expressao com alias tal como é mostrado no exemplo abaixo.

 Notas

       Variáveis declaradas: Uma cadeia de caracteres retornada
        pela funçao DBFILTER() podem nao operar corretamente quando forem
        recompiladas e executadas utilizando o operador macro (&) caso a
        expressao de filtragem original contenha referências a variáveis
        locais ou estáticas, ou se depende de declaraçoes em tempo de
        compilaçao.

 Exemplos

       Este exemplo abre dois arquivos de dados, configura dois
        filtros, e entao exibe as expressoes para ambas as áreas de
        trabalho:

        USE Customer INDEX Customer NEW
        SET FILTER TO Last = "Smith"
        USE Invoices INDEX Invoices NEW
        SET FILTER TO CustId = "Smi001"
        SELECT Customer
        //
        ? DBFILTER()                     // Resulta: CustId = "Smith"
        ? Invoices->(DBFILTER())         // Resulta: CustId = "Smi001"

       A funçao de usuário seguinte, CreateQry(), utiliza DBFILTER()
        para criar um arquivo de memória contendo a expressao de filtragem
        corrente na variável privada cFilter:

        FUNCTION CreateQry( cQryName )
           PRIVATE cFilter := DBFILTER()
           SAVE ALL LIKE cFilter TO (cQryName  + ".qwy")
           RETURN NIL

       Você pode restaurar mais tarde (RESTORE) um arquivo que
        contém uma pesquisa com a seguinte funçao do usuário, SetFilter():

        FUNCTION SetFilter( cQryName )
           RESTORE FROM &cQryName..qwy ADDITIVE
           SET FILTER TO &cFilter.
           RETURN NIL

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: DBRELATION() DBRSELECT() SET FILTER