FIELDBLOCK()
 Retorna um bloco de código set-get para um determinado campo
------------------------------------------------------------------------------

 Sintaxe

     FIELDBLOCK(<cNomeCampo>) --> bBlocoCampo

 Argumentos

     <CNomeCampo> é o nome do campo ao qual o bloco set-get se referirá.

 Retorno

     FIELDBLOCK() retorna um bloco de código que quando avaliado estabelece
     (set) ou recupera (get) o valor de um dado campo.  Se <cNomeCampo> nao
     existe na área corrente, FIELDBLOCK() retorna NIL.

 Descriçao

     FIELDBLOCK() é uma funçao de arquivo de dados que cria um bloco de
     código.  Quando executada com um argumento o bloco de código criado por
     esta funçao atribui o valor do argumento a <cNomeCampo>.  Quando
     executada sem argumento, o bloco de código recupera o valor de
     <cNomeCampo>.

 Notas

       Area de trabalho: O bloco de código retornado por
        FIELDBLOCK() estabelece ou recupera o valor do campo especificado em
        qualquer área de trabalho que seja a corrente quando o bloco seja
        executado.  Por exemplo, dadas as áreas 1 e 2, ambas contendo o
        campo FName:

        SELECT 1
        FName:= "Kate"
        SELECT 2
        FName := "Cindy"

        bFName := FIELDBLOCK("FName")

        SELECT 1
        ? EVAL(bFName)         // "Kate"
        SELECT 2
        ? EVAL(bFName)         // "Cindy"

        A funçao FIELDWBLOCK() fornece um bloco set-get para um campo numa
        área de trabalho específica.

 Exemplos

     O exemplo a seguir compara FIELDBLOCK() com um bloco de código criado
     usando o macro operador.  Note que usando FIELDBLOCK() permite-lhe
     evitar a perda de velocidade e ocréscimo no uso de memória causado pelo
     macro:

     // Bloco Set-Get definido usando macro
     bSetGet := &( "{ |setVal| IF( setVal == NIL, FName, FName := setVal ) }" )

     // Bloco Set-Get definido usando FIELDBLOCK()
     // bSetGet criado aqui é o equivalente funcional de bSetGet acima
     bSetGet := FIELDBLOCK("FName")

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: FIELDWBLOCK() MEMVARBLOCK()