READVAR()
 Retorna o nome da variável GET/MENU corrente
------------------------------------------------------------------------------

 Sintaxe

     READVAR() --> cNomeVar

 Retorno

     READVAR() retorna o nome da variável associada ao objeto GET corrente,
     ou a variável atribuida pelo comando MENU TO corrente na forma de uma
     cadeia de caracteres em letras maiúsculas.

 Descriçao

     READVAR() é uma funçao de tratamento de ambiente utilizada
     principalmente para implementar um auxílio sensível ao contexto para
     objetos GET e menus de barra luminosa.  READVAR() funciona somente
     durante um comando READ ou MENU TO.  Caso seja utilizada durante
     quaisquer outros estados de espera, tais como ACCEPT, INPUT, WAIT,
     ACHOICE(), DBEDIT(), ou MEMOEDIT(), ela retorna uma cadeia de
     caracteres nula ("").  Esta funçao é acessada em uma rotina SET KEY, ou
     em uma funçao definida pelo usuário invocada a partir de uma cláusula
     WHEN ou VALID de um objeto GET.

 Exemplos

     Este exemplo implementa um sistema de auxílio (help) simples para
     objetos GET, utilizando um arquivo de banco de dados para armazenar o
     texto de auxílio.  Quando o usuário pressiona F1, o arquivo de banco de
     dados de auxílio é pesquisado usando READVAR() como o valor chave.
     Caso haja texto de auxílio disponível, ele é exibido em uma janela:

     #include "Inkey.ch"
     //
     SET KEY K_F1 TO HelpLookup
     cString = SPACE(10)
     @ 5, 5 SAY "Digite:" GET cString
     READ
     RETURN

     FUNCTION HelpLookup
        USE Help INDEX Help NEW
        SEEK READVAR()
        IF FOUND()
           DisplayHelp(Help->Topic)
        ELSE
           DisplayHelp("Nao ha auxílio para " + READVAR())
        ENDIF
        CLOSE Help
        RETURN NIL

     FUNCTION DisplayHelp( cTopic )
        LOCAL cScreen := SAVESCREEN(5,5,15,70), cColor := SETCOLOR("BG+/B")
        //
        SET CURSOR OFF
        @ 5, 5 CLEAR TO 15, 70
        @ 5, 5 TO 15, 70 DOUBLE
        @ 5, 30 SAY " Auxílio para " + READVAR() + " "
        MEMOEDIT(cTopic, 6, 7, 14, 68, .F.)
        //
        RESTSCREEN(5, 5, 15, 70, cScreen)
        SETCOLOR(cColor)
        SET CURSOR ON
        //
        RETURN NIL

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: @...GET MENU TO READ SET KEY