RESTSCREEN()
 Exibe uma regiao de tela gravada em uma localizaçao especificada
------------------------------------------------------------------------------

 Sintaxe

     RESTSCREEN(<nTopo>, <nEsquerda>,
        <nBase>, <nDireita>, <cTela>) --> NIL

 Argumentos

     <nTopo>, <nEsquerda>, <nBase>, e <nDireita> definem as
     coordenadas da informaçao de tela contida em <cTela>.

     <cTela> é uma cadeia de caracteres que contém a regiao de tela
     gravada.

 Retorno

     RESTSCREEN() sempre retorna NIL.

 Descriçao

     RESTSCREEN() é uma funçao de tratamento de tela que re-exibe uma regiao
     de tela gravada com SAVESCREEN().  A localizaçao da tela destino pode
     ou nao ser a mesma que a localizaçao original de quando a regiao de
     tela foi gravada.  Se você especificar uma nova localizaçao de tela, a
     nova regiao de tela deve ser do mesmo tamanho, pois do contrário você
     poderá obter resultados ambíguos.  Para usar RESTSCREEN() a fim de
     recuperar regioes de tela gravadas com o comando SAVE SCREEN,
     especifique as coordenadas de regiao como 0, 0, MAXROW(), MAXCOL().

     -----------------------------------------------------------------------
     . Aviso

     SAVE SCREEN, RESTORE SCREEN, SAVESCREEN(), e RESTSCREEN() sao
     suportados quando se utiliza o driver de tela (mapeamento de memória
     IBM-PC) padrao.  Outros drivers de tela podem nao suportar a gravaçao e
     recuperaçao de telas.
     -----------------------------------------------------------------------

 Exemplos

     Este exemplo demonstra RESTSCREEN() como parte de uma funçao de menu
     pop-up de fins gerais, PopMenu():

     ? PopMenu({1, 1, 3, 15, {"Item Um", "Item Dois"}, "BG+/B"})

     FUNCTION PopMenu( aList )
        LOCAL cScreen, nChoice, cOldColor := SETCOLOR(aList[6])
        cScreen := SAVESCREEN(aList[1], aList[2], aList[3], aList[4])
        @ aList[1], aList[2], TO aList[3], aList[4] DOUBLE
        nChoice := ACHOICE(++aList[1], ++aList[2],;
           --aList[3], --aList[4], aList[5])
        SETCOLOR(cOldColor)
        RESTSCREEN(--aList[1], --aList[2], ++aList[3], ++aList[4], cScreen)
        RETURN nChoice

 Arquivos:  Biblioteca EXTEND.LIB.
 To download this example - click here.

See Also: SAVESCREEN()