ROW()
 Retorna a posiçao de linha do cursor na tela
------------------------------------------------------------------------------

 Sintaxe

     ROW() --> nLinha

 Retorno

     ROW() retorna a posiçao de linha do cursor na forma de um valor
     numérico inteiro.  A faixa do valor de retorno varia entre zero e
     MAXROW().

 Descriçao

     ROW() é uma funçao de tratamento de tela que retorna a posiçao corrente
     de linha do cursor de tela.  O valor de ROW() é atualizado por comandos
     e funçoes de console e tela completa.  @..SAY somente atualiza ROW()
     quando o dispositivo (DEVICE) corrente é a tela (SCREEN).

     ROW() é utilizada juntamente com COL() e todas as variaçoes do comando
     @ para posicionar o cursor em uma nova linha relativamente à linha
     corrente.  Você pode usar ROW() e COL() em especial para criar rotinas
     ou funçoes independentes da posiçao da tela, onde você passa linha e
     coluna superior esquerda como parâmetros.

     ROW() é relacionada a PROW() e PCOL(), as quais informam a posiçao
     corrente da cabeça de impressao ao invés da posiçao do cursor da tela.

 Exemplos

     Neste exemplo, ROW() é utilizada para simular o comando LIST, exibindo
     o texto na mesma linha porém em colunas diferentes:

     LOCAL nRow
     USE Customer INDEX CustName NEW
     WHILE !EOF()
        CLS
        @ 1, 1 SAY PADR("Nome", LEN(CustName))
        @ ROW(), COL() + 2 SAY PADR("Endereco", LEN(Address))
        @ ROW(), COL() + 2 SAY PADR("Fone", LEN(Phone))
        nRow = 0
        WHILE nRow++ <= 15 .AND. (!EOF())
           @ ROW() + 1, 1 SAY CustName
           @ ROW(), COL() + 2 SAY Address
           @ ROW(), COL() + 2 SAY Phone
           SKIP
        ENDDO
        WAIT
     ENDDO
     CLOSE Customer

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: COL() MAXROW() PROW() ?|?? @...SAY SET DEVICE