SAVESCREEN()
 Grava uma regiao de tela para posterior exibiçao
------------------------------------------------------------------------------

 Sintaxe

     SAVESCREEN(<nTopo>, <nEsquerda>,
        <nBase>, <nDireita>) --> cTela

 Argumentos

     <nTopo>, <nEsquerda>, <nBase>, e <nDireita> definem as
     coordenadas da regiao de tela a ser gravada.  Caso <nBase> ou
     <nDireita> seja maior do que MAXROW() ou MAXCOL(), a tela é cortada.

 Retorno

     SAVESCREEN() retorna a regiao de tela especificada na forma de uma
     cadeia de caracteres.

 Descriçao

     SAVESCREEN() é uma funçao de tratamento de tela, utilizada para gravar
     uma regiao de tela em uma variável de qualquer classe de armazenamento,
     inclusive variáveis de campo.  Mais tarde, você pode re-exibir a imagem
     de tela gravada na mesma ou em uma nova localizaçao, através da funçao
     RESTSCREEN().  Regioes de tela geralmente sao gravadas e recuperadas
     quando se utiliza uma rotina de menu pop-up ou quando se move um objeto
     de tela.

     -----------------------------------------------------------------------
     . Aviso

     SAVE SCREEN, RESTORE SCREEN, SAVESCREEN(), e RESTSCREEN() sao
     suportadas quando se utiliza o driver de tela (mapeamento de memória
     IBM-PC) padrao.  Outros drivers de tela podem nao suportar a gravaçao e
     a recuperaçao de telas.
     -----------------------------------------------------------------------

 Exemplos

     A seguinte funçao definida pelo usuário cria um menu pop-up utilizando
     ACHOICE() juntamente com SAVESCREEN() e RESTSCREEN(), retornando a
     seleçao no vetor de escolhas:

     FUNCTION PopMenu( nTop, nLeft, nBottom, nRight, aItems, cColor )
        LOCAL cScreen, nChoice, cLastColor := SETCOLOR(cColor)
        //
        cScreen = SAVESCREEN(nTop, nLeft, nBottom, nRight)
        @ nTop, nLeft TO nBottom, nRight DOUBLE
        //
        nChoice = ACHOICE(++nTop, ++nLeft, --nBottom, --nRight, aItems)
        //
        RESTSCREEN(--nTop, --nLeft, ++nBottom, ++nRight, cScreen)
        SETCOLOR(cLastColor)
        RETURN nChoice

 Arquivos:  Biblioteca EXTEND.LIB.
 To download this example - click here.

See Also: RESTSCREEN()