SETCANCEL()
 Comuta Alt-C como uma tecla de terminaçao de execuçao de programa
------------------------------------------------------------------------------

 Sintaxe

     SETCANCEL([<lComuta>]) --> lConfigCorrente

 Argumentos

     <lComuta> comuta Alt-C como uma tecla de terminaçao de execuçao de
     um programa.  Especificando-se verdadeiro (.T.) ativa a tecla, e falso
     (.F.) desativa.  O padrao é verdadeiro (.T.).

 Retorno

     SETCANCEL() retorna a configuraçao corrente como um valor lógico.

 Descriçao

     SETCANCEL() é uma funçao de tratamento de teclado que comuta o estado
     da tecla de terminaçao, Alt-C, e informa o estado corrente de
     SETCANCEL().  SETCANCEL() é utilizada quando você deseja suprimir a
     possibilidade do usuário de terminar um programa sem usar o método
     especificado.

     Note que se Alt-C for redefinido com SET KEY, a definiçao de SET KEY
     tem precedência, mesmo caso SETCANCEL() retorne verdadeiro (.T.).

     -----------------------------------------------------------------------
     . Cuidado

     Quando SETCANCEL() foi configurado em falso (.F.), o usuário nao pode
     terminar um programa a nao ser que você forneça um mecanismo de escape
     alternativo.
     -----------------------------------------------------------------------

 Exemplos

     Este exemplo demonstra como fornecer um mecanismo para escape de um
     estado de espera com SETCANCEL() em falso:

     #define K_ALTC  302
     //
     SETCANCEL(.F.)                 // Desabilita Alt-C como tecla de parada
     SET KEY K_ALTC TO AltC         // Redefine Alt-C
     .
     . <declaraçoes>
     .
     RETURN

     FUNCTION AltC
        LOCAL cScreen, nChoice, cLastColor := SETCOLOR("W/B, N/G")
        //
        SAVE SCREEN TO cScreen
        @ 6, 20 CLEAR TO 9, 58
        @ 6, 20 TO 9, 58 DOUBLE
        @ 7, 26 SAY "Alt-C: Voce quer sair?"
        @ 8, 35 PROMPT " Sim "
        @ 8, 41 PROMPT " Nao "
        MENU TO nChoice
        SETCOLOR(cLastColor)
        RESTORE SCREEN FROM cScreen
        //
        IF nChoice == 1
           QUIT
        ENDIF
        //
        RETURN NIL

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: ALTD() SET ESCAPE SET KEY