CONTINUE
 Reassume um LOCATE pendente
------------------------------------------------------------------------------

 Sintaxe

     CONTINUE

 Descriçao

     CONTINUE pesquisa a partir do registro corrente até encontrar o próximo
     registro que satisfaça a condiçao do LOCATE mais recente executado na
     área corrente.  Ele encerra-se quando a condiçao é obedecida ou atinge
     o fim do arquivo.  Se o CONTINUE tem sucesso, o registro encontrado
     torna-se o atual e FOUND() retorna verdadeiro (.T.), se nao houve
     sucesso FOUND() retorna falso (.F.).

     Cada área de trabalho pode ter uma condiçao de LOCATE ativa.  Em
     Clipper, uma condiçao de LOCATE fica pendente até que uma nova condiçao
     de locate seja especificada.  Nao existem comandos que liberem a
     condiçao.

 Notas

       Abrangência e WHILE: Note que a abrangência e a condiçao
        WHILE sao ignoradas; somente a condiçao FOR é usada pelo CONTINUE.
        Caso você esteja usando um LOCATE com WHILE e necessita continuar a
        busca por um registro que obedeça à condiçao, repita o LOCATE
        adicionando a abrangência REST.

 Exemplos

       Este exemplo procura registros em Sales.dbf para um vendedor
        qualquer e exibe um total de vendas:

        LOCAL nRunTotal := 0
        USE Sales NEW
        LOCATE FOR Sales->Salesman = "1002"
        DO WHILE FOUND()
           ? Sales->Salesname, nRunTotal += Sales->Amount
           CONTINUE
        ENDDO

       Este exemplo demonstra como reassumir o LOCATE pendente com
        WHILE:

        LOCAL nRunTotal := 0
        USE Sales INDEX Salesman NEW
        SEEK "1002"
        LOCATE REST WHILE Sales->Salesman = "1002" FOR Sales->Amount > 5000
        DO WHILE FOUND()
           ? Sales->Salesname, nRunTotal += Sales->Amount
           LOCATE REST WHILE Sales->Salesman = "1002" FOR Sales->Amount > 5000
        ENDDO

 Arquivos:  Biblioteca CLIPPER.LIB.
 To download this example - click here.

See Also: LOCATE SEEK EOF() FOUND()