RUN
 Executa um programa ou comando DOS
------------------------------------------------------------------------------

 Sintaxe

     RUN | !* <xcLinhaComando>

 Argumentos

     <xcLinhaComando> é qualquer programa executável, inclusive os
     comandos residentes DOS e COMMAND.COM.  Pode ser especificado
     literalmente ou por expressao caractere entre parênteses.

 Descriçao

     O comando RUN executa um comando ou programa DOS de dentro de uma
     aplicaçao compilada.  Quando você utiliza o comando RUN num programa
     DOS, o Clipper executa outra cópia de COMMAND.COM, passando a linha de
     comando DOS ao mesmo tempo.  Isto tem duas implicaçoes.  A primeira é
     que você deve ter memória suficiente para o COMMAND.COM (27K para DOS
     3.2) e o programa que você deseja executar.  A segunda é que o
     COMMAND.COM deve estar disponível no local especificado pelo COMSPEC (o
     padrao é o diretório raiz do disco onde você carregou o DOS).  Se o
     COMMAND.COM nao estiver localizado neste disco ou o disco for trocado,
     mude SET COMSPEC para a nova localizaçao antes de executar a operaçao
     Clipper.  Observe que os comandos SET DEFAULT e SET PATH nao têm efeito
     algum sobre o comando RUN.

     A forma ! do comando RUN é fornecida unicamente por razoes de
     compatibilidade e, portanto, desaconselhada.

     -----------------------------------------------------------------------
     . Aviso

     Nao utilize o comando RUN para instalar programas residentes em memória
     de dentro do Clipper porque pode haver perda de memória quando o
     controle retornar ao seu programa aplicativo.
     -----------------------------------------------------------------------

 Exemplos

       O exemplo seguinte demonstra como utilizar o comando RUN
        combinado com as funçoes MEMOREAD() e MEMOWRIT() para criar uma
        funçao definida por usuário que chama seu editor com o campo memo
        corrente:

        lSuccess = EditorMemo("Brief", "Notes")
        RETURN

        FUNCTION EditorMemo( cEditor, cMemofld )
           IF MEMOWRIT("Clipedit.tmp", &cMemofld.)
              RUN (cEditor + " Clipedit.tmp")
              REPLACE &cMemofld. WITH MEMOREAD("Clipedit.tmp")
              ERASE Clipedit.tmp
              RETURN .T.
           ELSE
              RETURN .F.
           ENDIF

       Uma das opçoes que você pode desejar oferecer a seus usuários
        é o acesso direto ao DOS.  Você pode fazer isso com o comando:

        RUN COMMAND

        Para facilitar ao usuário o retorno ao programa de aplicaçao, mude o
        prompt DOS no arquivo batch de aplicaçao desta forma:

        REM Application batch file
        ECHO OFF
        PROMPT Acesso ao DOS: Digite EXIT para retornar ao programa $_$p$g
        <seu programa aplicativo>
        PROMPT $p$g

        Depois, instrua o usuário a executar o arquivo batch de aplicaçao em
        lugar do aplicativo .EXE.

 Arquivos:  Bilbioteca CLIPPER.LIB.