<> != #
 Nao Igual -- binário                              (Relacional)
------------------------------------------------------------------------------

 Sintaxe

     <exp1> <> <exp2>
     <exp1> != <exp2>
     <exp1> #  <exp2>

 Tipo:  Caracter, data, lógico, NIL, numérico, memo

 Operandos

     <exp1> e <exp2> sao expressao do mesmo tipo ou NIL para
     comparar pela desigualdade.

 Descriçao

     O <> (nao igual) é um operador binário que compara dos valores do mesmo
     tipo de dado e retorna (.T.) se <exp1> nao for igual a <exp2> de acordo
     com as regras a seguir:

     ■  Caractere: A comparaçao é baseada no código ASCII e é o
        inverso do operador igual (=).  Isto significa que a comparaçao é
        sensivel ao SET EXACT corrente.  Veja os exemplos abaixo.

     ■  Date: Datas sao comparadas de acordo com o valor base das
        datas.

     ■  Lógicol: Falso (.F.) nao é igual a verdadeiro (.T.).

     ■  Memo: Tratado como caractere.

     ■  NIL: Todos valores comparados com NIL que nao sejam NIL
        retornam verdadeiro (.T.).

     ■  Numérico: Comparados baseados na magnitude.

 Exemplos

     // Caractere
     SET EXACT ON
     ? "123" <> "12345"                 // Resulta: .T.
     ? "12345" <> "123"                 // Resulta: .T.
     ? "123" <> ""                      // Resulta: .T.
     ? "" <> "123"                      // Resulta: .T.

     SET EXACT OFF
     ? "123" <> "12345"                 // Resulta: .T.
     ? "12345" <> "123"                 // Resulta: .F.
     ? "123" <> ""                      // Resulta: .F.
     ? "" <> "123"                      // Resulta: .T.

     // Data
     ? CTOD("12/12/88") <> CTOD("12/12/88")      // Resulta: .F.

     // Lógico
     ? .T. <> .T.                       // Resulta: .F.
     ? .T. <> .F.                       // Resulta: .T.

     // NIL
     ? NIL <> NIL                       // Resulta: .F.
     ? NIL <> 12                        // Resulta: .T.
     ? NIL <> "Lady Dragon"             // Resulta: .T.

     // Numérico
     ? 2 <> 1                           // Resulta: .T.
     ? 1 <> 1                           // Resulta: .F.
 To download this example - click here.

See Also: $ < > = (igualdade) == >= <=