=
 Igual -- binário                                  (Relacional)
------------------------------------------------------------------------------

 Sintaxe

     <exp1> = <exp2>

 Tipo:  Caractere, data, lógico, memo, NIL, numérico

 Operandos

     <exp1> e <exp2> sao expressoes do mesmo tipo de dado a serem
     comparadas.

 Descriçao

     O = (igual) é um operador binário que compara dois valores do mesmo
     tipo de dado retornando verdadeiro (.T.) se <exp1> é igual a <exp2>
     conforme as seguintes regras:

     ■  Caractere: A comparaçao é baseada no código ASCII base.
        Lembre-se que códigos ASCII para caracteres alfabéticos sao
        ascendentes (p.exe., o código para "A" é 65 e o código para "Z" é
        90).

        Quando EXACT está OFF dois strings sao comparados de acordo com as
        seguintes regras; asumindo dois strings cLeft e cRight onde a
        expressao a ser testada é (cLeft = cRight):

        .  Caso cRight seja nulo, retorna verdadeiro (.T.).

        .  Caso LEN(cRight) seja maior que LEN(cLeft), retorna falso
           (.F.).

        .  Compara todos os caracteres em cRight com cLeft.  Se todos
           os caracteres em cRight forem iguais a cLeft, retorna verdadeiro
           (.T.); senao retorna falso (.F.).

        Com EXACT ON, dois strings devem corresponder exatamente, exceto
        pelos espaços a direita.

     ■  Data: Datas sao comparadas de acordo com o valor base data.

     ■  Lógico: Verdadeiro (.T.) é igual a verdadeiro (.T.) e falso
        (.F.) é igual a falso (.F.).

     ■  Memo: Tratado da mesma forma que caractere.

     ■  NIL: Verdadeiro (.T.) se é comparado com um valor; falso
        (.F.) se comparado com valor de outro tipo.

     ■  Numérico: Comparado baseado na magnitude.

 Exemplos

     // Caractere
     SET EXACT ON
     ? "123" = "123  "         // Resulta: .T.
     ? " 123" = "123"          // Resulta: .F.

     SET EXACT OFF
     ? "123" = "12345"         // Resulta: .F.
     ? "12345" = "123"         // Resulta: .T.
     ? "123" = ""              // Resulta: .T.
     ? "" = "123"              // Resulta: .F.

     // Data
     ? CTOD("12/12/88") = CTOD("12/12/88")       // Resulta: .T.

     // Lógico
     ? .T. = .T.               // Resulta: .T.
     ? .F. = .F.               // Resulta: .T.

     // NIL
     ? NIL = NIL               // Resulta: .T.
     ? NIL = 12                // Resulta: .F.
     ? NIL = CTOD("")          // Resulta: .F.

     // Numerico
     ? 2 = 1                   // Resulta: .F.
     ? 1 = 1                   // Resulta: .T.
 To download this example - click here.

See Also: $ < > == >= <= <>